reserve E,V for set, G,G1,G2 for _Graph, c,c1,c2 for Cardinal, n for Nat;
reserve f for VColoring of G;
reserve g for EColoring of G;

theorem Th97:
  for F being PGraphMapping of G1,G, g9 being EColoring of G1
  st dom F_E = the_Edges_of G1 & F_E is one-to-one & g9 = g*(F_E) & g is proper
  holds g9 is proper
proof
  let F be PGraphMapping of G1, G, g9 be EColoring of G1;
  assume A1: dom F_E = the_Edges_of G1 & F_E is one-to-one &
    g9 = g*(F_E) & g is proper;
  now
    let v be Vertex of G1, e1, e2 be object;
    assume A2: e1 in v.edgesInOut() & e2 in v.edgesInOut() & g9.e1 = g9.e2;
    then A3: g9.e1 = g.(F_E.e1) & g9.e2 = g.(F_E.e2) by A1, FUNCT_1:13;
    (the_Source_of G1).e1 = v or (the_Target_of G1).e1 = v by A2, GLIB_000:61;
    then v in dom F_V by A1, A2, GLIB_010:5;
    then A4: F_E.:(v.edgesInOut()) c= (F_V/.v).edgesInOut() by GLIBPRE0:80;
    F_E.e1 in F_E.:(v.edgesInOut()) & F_E.e2 in F_E.:(v.edgesInOut())
      by A1, A2, FUNCT_1:def 6;
    then F_E.e1 in (F_V/.v).edgesInOut() & F_E.e2 in (F_V/.v).edgesInOut()
      by A4;
    then F_E.e1 = F_E.e2 by A1, A2, A3, Th85;
    hence e1 = e2 by A1, A2, FUNCT_1:def 4;
  end;
  hence thesis by Th85;
end;
