reserve            x for object,
               X,Y,Z for set,
         i,j,k,l,m,n for Nat,
                 r,s for Real,
                  no for Element of OrderedNAT,
                   A for Subset of [:NAT,NAT:];
reserve X,Y,X1,X2 for non empty set,
          cA1,cB1 for filter_base of X1,
          cA2,cB2 for filter_base of X2,
              cF1 for Filter of X1,
              cF2 for Filter of X2,
             cBa1 for basis of cF1,
             cBa2 for basis of cF2;
reserve T for non empty TopSpace,
        s for Function of [:NAT,NAT:], the carrier of T,
        M for Subset of the carrier of T;
reserve cF3,cF4 for Filter of the carrier of T;
reserve Rseq for Function of [:NAT,NAT:],REAL;
reserve f for Function of [#]OrderedNAT,R^1,
        seq for Function of NAT,REAL;
reserve Y for non empty TopSpace,
        x for Point of Y,
        f for Function of [:X1,X2:],Y;

theorem Th77:
  x in lim_filter(f,<.cF1,cF2.)) & <.cB1.) = cF1 & <.cB2.) = cF2
  implies for U being a_neighborhood of x st U is closed holds
  ex B1 being Element of cB1, B2 being Element of cB2 st
  for z being Element of X2, y being Element of Y st z in B2 &
  y in lim_filter(ProjMap2(f,z),cF1) holds y in Cl Int U
  proof
    assume that
A1:  x in lim_filter(f,<.cF1,cF2.)) and
A2:  <.cB1.) = cF1 and
A3:  <.cB2.) = cF2;
    let U be a_neighborhood of x;
    assume U is closed;
    then consider B1 be Element of cB1,B2 be Element of cB2 such that
A4: f.:([:B1,B2:]) c= Int U by A1,A2,A3,Th75;
    take B1,B2;
A5: for y be Element of B2 holds f.:([:B1,{y}:]) c= Int U
    proof
      let y be Element of B2;
      [:B1,{y}:] c= [:B1,B2:] by ZFMISC_1:95;
      then f.:([:B1,{y}:]) c=f.:([:B1,B2:]) by RELAT_1:125;
      hence thesis by A4;
    end;
A6: for z be Element of B2, y be Element of Y st
    y in lim_filter(ProjMap2(f,z),cF1)
    holds filter_image(ProjMap2(f,z),cF1) is
      proper Filter of BoolePoset [#]Y &
      Int U in filter_image(ProjMap2(f,z),cF1) &
      y is_a_cluster_point_of filter_image(ProjMap2(f,z),cF1),Y
    proof
      let z be Element of B2,y be Element of Y;
      assume
A7:   y in lim_filter(ProjMap2(f,z),cF1);
      filter_image(ProjMap2(f,z),cF1) is Filter of [#]Y by STRUCT_0:def 3;
      hence filter_image(ProjMap2(f,z),cF1) is
        proper Filter of BoolePoset [#]Y by Th17;
A8:   ProjMap2(f,z)"(Int U) is Subset of X1
      proof
        dom ProjMap2(f,z) = X1 by FUNCT_2:def 1;
        hence thesis by RELAT_1:132;
      end;
A9:   for z be Element of B2 holds ProjMap2(f,z).:B1 c= Int U
      proof
        let z be Element of B2;
        let t be object;
        assume t in ProjMap2(f,z).:B1;
        then consider u be object such that
        u in dom ProjMap2(f,z) and
A10:    u in B1 and
A11:    t = ProjMap2(f,z).u by FUNCT_1:def 6;
        ProjMap2(f,z).u = f.(u,z) by A10,MESFUNC9:def 7; then
A12:    t = f.([u,z]) by A11,BINOP_1:def 1;
        now
          [u,z] in [:X1,X2:] by A10,ZFMISC_1:def 2;
          hence [u,z] in dom f by FUNCT_2:def 1;
          z in {z} & u in B1 by TARSKI:def 1,A10;
          hence [u,z] in [:B1,{z}:] by ZFMISC_1:def 2;
        end;
        then VALB:t in f.:([:B1,{z}:]) by A12,FUNCT_1:def 6;
        f.:([:B1,{z}:]) c= Int U by A5;
        hence thesis by VALB;
      end;
      thus Int U in filter_image(ProjMap2(f,z),cF1) &
        y is_a_cluster_point_of filter_image(ProjMap2(f,z),cF1),Y
      proof
        ProjMap2(f,z).:B1 c= Int U by A9;
        then B1 c= ProjMap2(f,z)"(Int U) by FUNCT_2:95;
        then ProjMap2(f,z)"(Int U) in cF1 by A2,A8,CARDFIL2:def 8;
        hence Int U in filter_image(ProjMap2(f,z),cF1);
        thus thesis by A7,Th19;
      end;
    end;
    for z be Element of B2, y be Element of Y st
      y in lim_filter(ProjMap2(f,z),cF1) holds y in Cl Int U
    proof
      let z be Element of B2, y be Element of Y;
      assume y in lim_filter(ProjMap2(f,z),cF1);
      then filter_image(ProjMap2(f,z),cF1) is
        proper Filter of BoolePoset [#]Y &
        Int U in filter_image(ProjMap2(f,z),cF1) &
        y is_a_cluster_point_of filter_image(ProjMap2(f,z),cF1),Y by A6;
      hence thesis by YELLOW19:25;
    end;
    hence thesis;
  end;
