
theorem Th98:
  for p1,p2,p3,p4 being Point of TOP-REAL 2, a,b,c,d being Real
, f,g being Function of I[01],TOP-REAL 2 st a<b & c < d & p1`1=a & p2`2=d
& p3`2= c & p4`2= c & c <=p1`2 & p1`2<=d & a<=p2`1 & p2`1<=b & a <p4`1 & p4`1<
p3`1 & p3`1<=b & f.0=p1 & f.1=p3 & g.0=p2 & g.1=p4 & f is continuous one-to-one
  & g is continuous one-to-one & rng f c= closed_inside_of_rectangle(a,b,c,d) &
  rng g c= closed_inside_of_rectangle(a,b,c,d) holds rng f meets rng g
proof
  reconsider O=0,I=1 as Point of I[01] by BORSUK_1:40,XXREAL_1:1;
  let p1,p2,p3,p4 be Point of TOP-REAL 2, a,b,c,d be Real, f,g be
  Function of I[01],TOP-REAL 2;
  assume that
A1: a<b and
A2: c < d and
A3: p1`1=a and
A4: p2`2=d and
A5: p3`2= c and
A6: p4`2= c and
A7: c <=p1`2 and
A8: p1`2<=d and
A9: a<=p2`1 and
A10: p2`1<=b and
A11: a <p4`1 and
A12: p4`1<p3`1 and
A13: p3`1<=b and
A14: f.0=p1 and
A15: f.1=p3 and
A16: g.0=p2 and
A17: g.1=p4 and
A18: f is continuous one-to-one and
A19: g is continuous one-to-one and
A20: rng f c= closed_inside_of_rectangle(a,b,c,d) and
A21: rng g c= closed_inside_of_rectangle(a,b,c,d);
  set A=2/(b-a), B=-(b+a)/(b-a), C = 2/(d-c), D=-(d+c)/(d-c);
  set h=AffineMap(A,B,C,D);
  reconsider g2= h*g as Function of I[01],TOP-REAL 2;
A22: g2 is continuous one-to-one by A1,A2,A19,Th53;
A23: p4`1<b by A12,A13,XXREAL_0:2;
  then
A24: -1<((g2).I)`1 by A1,A11,A17,Th64;
A25: (g.I)`2= c by A6,A17;
  then
A26: -1 <=((g2).O)`1 by A1,A9,A10,A11,A16,A17,A23,Th64;
A27: ((g2).O)`1<=1 by A1,A9,A10,A11,A16,A17,A23,A25,Th64;
  d-c >0 by A2,XREAL_1:50;
  then
A28: C >0 by XREAL_1:139;
  reconsider f2= h*f as Function of I[01],TOP-REAL 2;
A29: f2 is continuous one-to-one by A1,A2,A18,Th53;
A30: p3`1 > a by A11,A12,XXREAL_0:2;
  then
A31: ((f2).I)`1<=1 by A1,A2,A5,A13,A15,Th61;
A32: (f.I)`2= c by A5,A15;
  then
A33: ((f2).O)`2<=1 by A1,A2,A7,A8,A13,A14,A15,A30,Th61;
  set x = the Element of rng f2 /\ rng g2;
A34: dom g=the carrier of I[01] by FUNCT_2:def 1;
  then
A35: h.p4=g2.I by A17,FUNCT_1:13;
A36: ((g2).I)`2= -1 by A2,A6,A17,Th57;
A37: ((g2).O)`2= 1 by A2,A4,A16,Th55;
  b-a>0 by A1,XREAL_1:50;
  then
A38: A >0 by XREAL_1:139;
  then h is being_homeomorphism by A28,Th50;
  then
A39: h is one-to-one by TOPS_2:def 5;
A40: rng (g2) c= closed_inside_of_rectangle(-1,1,-1,1) by A1,A2,A21,Th52;
A41: rng (f2) c= closed_inside_of_rectangle(-1,1,-1,1) by A1,A2,A20,Th52;
A42: ((f2).I)`2= -1 by A2,A5,A15,Th57;
A43: ((f2).O)`1= -1 by A1,A3,A14,Th54;
A44: dom f=the carrier of I[01] by FUNCT_2:def 1;
  then h.p3=f2.I by A15,FUNCT_1:13;
  then
A45: ((g2).I)`1< ((f2).I)`1 by A12,A38,A28,A35,Th50;
  -1 <=((f2).O)`2 by A1,A2,A7,A8,A13,A14,A15,A30,A32,Th61;
  then rng f2 meets rng g2 by A29,A43,A42,A33,A31,A41,A22,A37,A36,A26,A27,A24
,A40,A45,Th29,JGRAPH_6:79;
  then
A46: rng f2 /\ rng g2 <>{} by XBOOLE_0:def 7;
  then x in rng g2 by XBOOLE_0:def 4;
  then consider z2 being object such that
A47: z2 in dom g2 and
A48: x=g2.z2 by FUNCT_1:def 3;
A49: x=h.(g.z2) by A34,A47,A48,FUNCT_1:13;
A50: g.z2 in rng g by A34,A47,FUNCT_1:def 3;
  g.z2 in the carrier of TOP-REAL 2 by A47,FUNCT_2:5;
  then
A51: g.z2 in dom h by FUNCT_2:def 1;
  x in rng f2 by A46,XBOOLE_0:def 4;
  then consider z1 being object such that
A52: z1 in dom f2 and
A53: x=f2.z1 by FUNCT_1:def 3;
A54: f.z1 in rng f by A44,A52,FUNCT_1:def 3;
  f.z1 in the carrier of TOP-REAL 2 by A52,FUNCT_2:5;
  then
A55: f.z1 in dom h by FUNCT_2:def 1;
  x=h.(f.z1) by A44,A52,A53,FUNCT_1:13;
  then f.z1=g.z2 by A49,A55,A51,A39,FUNCT_1:def 4;
  hence thesis by A54,A50,XBOOLE_0:3;
end;
