reserve a,b,c,h for Integer;
reserve k,m,n for Nat;
reserve i,j,z for Integer;
reserve p for Prime;

theorem Th98:
  for m,D being positive natural Number, a,b being Nat st a < b holds
  (exampleSierpinski150(m,D).a)`1 < (exampleSierpinski150(m,D).b)`1 &
  (exampleSierpinski150(m,D).a)`2 < (exampleSierpinski150(m,D).b)`2
  proof
    let m,D be positive natural Number;
    let a,b be Nat such that
A1: a < b;
    set f = exampleSierpinski150(m,D);
    defpred P[Nat] means
    $1 > a implies (f.$1)`1 > (f.a)`1 & (f.$1)`2 > (f.a)`2;
A2: P[0];
A3: for k being Nat holds P[k] implies P[k+1]
    proof
      let k be Nat;
      assume that
A4:   P[k] and
A5:   k+1 > a;
A6:   f.(k+1) = [ (f.k)`1^2+D*(f.k)`2^2 , 2*(f.k)`1*(f.k)`2 ] by Def19;
A7:   (f.k)`1 >= 0+1 by NAT_1:13;
      then 2*(f.k)`1 >= 2*1 by XREAL_1:64;
      then
A8:   2*(f.k)`1 > 1 by XXREAL_0:2;
A9:   (f.k)`1^2 >= 1*(f.k)`1 by A7,XREAL_1:64;
      k >= a by A5,NAT_1:13;
      then per cases by XXREAL_0:1;
      suppose
A10:    k > a;
        (f.k)`1^2 + D*(f.k)`2^2 >= (f.k)`1 + 0 by A9,XREAL_1:7;
        hence (f.(k+1))`1 > (f.a)`1 by A4,A6,A10,XXREAL_0:2;
        2*(f.k)`1*(f.k)`2 >= (f.k)`2*1 by A8,XREAL_1:68;
        hence (f.(k+1))`2 > (f.a)`2 by A4,A6,A10,XXREAL_0:2;
      end;
      suppose
A11:    k = a;
        (f.k)`1^2 + D*(f.k)`2^2 > (f.k)`1 + 0 by A9,XREAL_1:8;
        hence (f.(k+1))`1 > (f.a)`1 by A6,A11;
        2*(f.k)`1 * (f.k)`2 > 1 * (f.k)`2 by A8,XREAL_1:68;
        hence (f.(k+1))`2 > (f.a)`2 by A6,A11;
      end;
    end;
    for k being Nat holds P[k] from NAT_1:sch 2(A2,A3);
    hence thesis by A1;
  end;
