
theorem :: Lemma_4_5_iv_i:
  for R being non empty doubleLoopStr st not ex F being sequence of
  bool (the carrier of R) st (for i being Element of NAT holds F.i is Ideal
  of R) & (for j,k being Element of NAT st j < k holds F.j c< F.k) holds R is
  Noetherian
proof
  let R being non empty doubleLoopStr such that
A1: not ex F being sequence of  bool (the carrier of R) st (for i
  being Element of NAT holds F.i is Ideal of R) & (for j,k being Element of NAT
  st j < k holds F.j c< F.k) and
A2: not R is Noetherian;
  consider I being Ideal of R such that
A3: I is not finitely_generated by A2;
  set D = { S where S is Subset of R : S is non empty finite Subset of I };
  consider e being object such that
A4: e in I by XBOOLE_0:def 1;
  reconsider e as Element of R by A4;
  {e} c= I by A4,ZFMISC_1:31;
  then
A5: {e} in D;
  D c= bool the carrier of R
  proof
    let x be object;
    assume x in D;
    then
    ex s being Subset of R st x = s & s is non empty finite Subset of I;
    hence thesis;
  end;
  then reconsider D as non empty Subset-Family of R by A5;
  reconsider e9={e} as Element of D by A5;
  defpred P[set,Element of D,set] means ex r being Element of R st r in I \ $2
  -Ideal & $3 = $2 \/ {r};
A6: for n be Nat for x be Element of D ex y be Element of D st P
  [n,x,y]
  proof
    let n be Nat, x be Element of D;
    x in D;
    then consider x9 being Subset of R such that
A7: x9 = x and
A8: x9 is non empty finite Subset of I;
    reconsider x19=x9 as non empty finite Subset of I by A8;
    x9-Ideal c= I-Ideal by A8,Th57;
    then x9-Ideal c= I by Th44;
    then not I c= x9-Ideal by A3,A8,XBOOLE_0:def 10;
    then consider r being object such that
A9: r in I and
A10: not r in x9-Ideal;
    set y=x19 \/ {r};
A11: y c= I
    proof
      let x be object;
      assume x in y;
      then x in x19 or x in {r} by XBOOLE_0:def 3;
      hence thesis by A9,TARSKI:def 1;
    end;
    then y is Subset of R by XBOOLE_1:1;
    then
A12: y in D by A11;
    reconsider r as Element of R by A9;
    reconsider y as Element of D by A12;
    take y;
    take r;
    thus thesis by A7,A9,A10,XBOOLE_0:def 5;
  end;
  consider f be sequence of  D such that
A13: f.0 = e9 & for n be Nat holds P[n,(f.n) qua Element of D
  ,f.(n+1)] from RECDEF_1:sch 2(A6);
  defpred Q[Nat,Subset of R] means ex c being Subset of R st c = f.
  $1 & $2 = c-Ideal;
A14: for x being Element of NAT ex y being Subset of R st Q[x,y]
  proof
    let x be Element of NAT;
    f.x in D;
    then consider c being Subset of R such that
A15: c = f.x and
    c is non empty finite Subset of I;
    reconsider y = c-Ideal as Subset of R;
    take y;
    take c;
    thus thesis by A15;
  end;
  consider F being sequence of  bool the carrier of R such that
A16: for x being Element of NAT holds Q[x,F.x] from FUNCT_2:sch 3(A14);
A17: for x being Nat holds Q[x,F.x]
    proof let x be Nat;
      x in NAT by ORDINAL1:def 12;
     hence thesis by A16;
    end;
A18: for j,k being Element of NAT st j < k holds F.j c< F.k
  proof
    let j,k be Element of NAT;
    defpred P[Nat] means F.j c< F.(j+1+$1);
    assume j < k;
    then j+1 <= k by NAT_1:13;
    then consider i being Nat such that
A19: k = j + 1 + i by NAT_1:10;
A20: for i being Nat holds F.i c< F.(i+1)
    proof
      let i be Nat;
      consider c being Subset of R such that
A21:  c = f.i and
A22:  F.i = c-Ideal by A17;
      consider c1 being Subset of R such that
A23:  c1 = f.(i+1) and
A24:  F.(i+1) = c1-Ideal by A17;
A25:  c1 c= c1-Ideal by Def14;
      consider r being Element of R such that
A26:  r in I \ c-Ideal and
A27:  c1 = c \/ {r} by A13,A21,A23;
      c in D by A21;
      then
      ex c9 being Subset of R st c9 = c & c9 is non empty finite Subset of I;
      hence F.i c= F.(i+1) by A22,A24,A27,Th57,XBOOLE_1:7;
      r in {r} by TARSKI:def 1;
      then r in c1 by A27,XBOOLE_0:def 3;
      hence thesis by A22,A24,A26,A25,XBOOLE_0:def 5;
    end;
A28: for i being Nat st P[i] holds P[i+1]
    proof
      let i be Nat such that
A29:  F.j c= F.(j+1+i) and
      F.j <> F.(j+1+i);
A30:  F.(j+1+i) c< F.((j+1+i)+1) by A20;
      then F.(j+1+i) c= F.((j+1+i)+1);
      hence F.j c= F.(j+1+(i+1)) by A29;
      thus thesis by A29,A30,XBOOLE_0:def 8;
    end;
A31: P[0] by A20;
A32: for i being Nat holds P[i] from NAT_1:sch 2(A31, A28);
    thus thesis by A32,A19;
  end;
  for i being Element of NAT holds F.i is Ideal of R
  proof
    let i be Element of NAT;
    ex c being Subset of R st c = f.i & F.i = c-Ideal by A17;
    hence thesis;
  end;
  hence contradiction by A1,A18;
end;
