reserve m,n,i,i2,j for Nat,
  r,r1,r2,s,t for Real,
  x,y,z for object;
reserve p,p1,p2,p3,q,q1,q2,q3,q4 for Point of TOP-REAL n;
reserve u for Point of Euclid n;
reserve R for Subset of TOP-REAL n;
reserve P,Q for Subset of TOP-REAL n;
reserve D for non vertical non horizontal non empty compact Subset of TOP-REAL
  2;

theorem Th83:
  for p being Point of TOP-REAL n, P being Subset of TOP-REAL n
  st n>=1 & P={p} holds P is boundary
proof
  let p be Point of TOP-REAL n, P be Subset of TOP-REAL n;
  assume that
A1: n>=1 and
A2: P={p};
  the carrier of (TOP-REAL n) c= Cl (P`)
  proof
    let z be object;
    assume
A3: z in the carrier of TOP-REAL n;
    per cases;
    suppose
A4:   z=p;
      reconsider ez=z as Point of Euclid n by A3,TOPREAL3:8;
      for G1 being Subset of (TOP-REAL n) st G1 is open holds z in G1
      implies (P`) meets G1
      proof
        let G1 be Subset of TOP-REAL n;
        assume
A5:     G1 is open;
        thus z in G1 implies (P`) meets G1
        proof
A6:       the TopStruct of TOP-REAL n = TopSpaceMetr Euclid n by EUCLID:def 8;
          then reconsider GG = G1 as Subset of TopSpaceMetr Euclid n;
          assume
A7:       z in G1;
          GG is open by A5,A6,PRE_TOPC:30;
          then consider r be Real such that
A8:       r>0 and
A9:       Ball(ez,r) c= GG by A7,TOPMETR:15;
          reconsider r as Real;
          set p2=p-(r/2/sqrt n)*(1.REAL n);
          reconsider ep2=p2 as Point of Euclid n by TOPREAL3:8;
A10:      0<sqrt n by A1,SQUARE_1:25;
A11:      |.p-p2.|=|.p-p+(r/2/sqrt n)*(1.REAL n).| by RLVECT_1:29
            .=|.(r/2/sqrt n)*(1.REAL n)+p-p.| by RLVECT_1:def 3
            .=|.(r/2/sqrt n)*(1.REAL n).| by RLVECT_4:1
            .=|.r/2/sqrt n.|*|.(1.REAL n).| by TOPRNS_1:7
            .=|.r/2/sqrt n.|*(sqrt n) by EUCLID:73
            .=|.r/2.|/|.sqrt n.|*(sqrt n) by COMPLEX1:67
            .=|.r/2.|/(sqrt n)*(sqrt n) by A10,ABSVALUE:def 1
            .=|.r/2.| by A10,XCMPLX_1:87
            .=r/2 by A8,ABSVALUE:def 1;
          r/2>0 by A8,XREAL_1:139;
          then p<>p2 by A11,TOPRNS_1:28;
          then not p2 in P by A2,TARSKI:def 1;
          then
A12:      p2 in P` by XBOOLE_0:def 5;
          r/2<r by A8,XREAL_1:216;
          then dist(ez,ep2)<r by A4,A11,JGRAPH_1:28;
          then p2 in Ball(ez,r) by METRIC_1:11;
          hence thesis by A9,A12,XBOOLE_0:3;
        end;
      end;
      hence thesis by A3,PRE_TOPC:def 7;
    end;
    suppose
      z<>p;
      then not z in P by A2,TARSKI:def 1;
      then
A13:  z in P` by A3,XBOOLE_0:def 5;
      P` c= Cl(P`) by PRE_TOPC:18;
      hence thesis by A13;
    end;
  end;
  then Cl (P`)=[#] (TOP-REAL n);
  then P` is dense by TOPS_1:def 3;
  hence thesis by TOPS_1:def 4;
end;
