reserve A,B for Ordinal,
        o for object,
        x,y,z for Surreal,
        n for Nat,
        r,r1,r2 for Real;

theorem Th99:
  for r be non-zero Sequence of REAL,
    y be strictly_decreasing Surreal-Sequence
  holds dom r/\dom y c= born Sum(r,y)
proof
  let r be non-zero Sequence of REAL,
  y be strictly_decreasing Surreal-Sequence;
  set s = Partial_Sums(r,y);
A1:dom s = succ (dom r/\dom y) by Def17;
  Sum(r,y) in_meets_terms s,y,r,(dom r/\dom y) & s,y,r simplest_up_to dom s
  by Def17,Th89;
  then
A2:rng born (s|dom s) c= succ born_eq Sum(r,y) by XBOOLE_1:17,Th98,A1;
A3: born_eq Sum(r,y) = born Sum(r,y) by SURREALO:48;
  succ (dom r/\dom y) c= succ born Sum(r,y)
  proof
    let o be Ordinal;
    assume
A4: o in succ (dom r/\dom y);
A5: o in dom s by A4,Def17;
    then s.o in rng s by FUNCT_1:def 3;
    then reconsider so=s.o as uSurreal by SURREALO:def 12;
A6: dom (born s) = dom s by Def20;
A7: born so = (born s).o by A5,Def20;
    then
A8: born so in rng born s by A6,A5,FUNCT_1:def 3;
    o c= (born s).o by A5,A6,ORDINAL4:10;
    hence thesis by A7,A8,A2,A3,ORDINAL1:12;
  end;
  then dom r/\dom y in succ born Sum(r,y) by ORDINAL1:21;
  hence thesis by ORDINAL1:22;
end;
