reserve AP for AffinPlane,
  a,a9,b,b9,c,c9,x,y,o,p,q,r,s for Element of AP,
  A,C,C9,D,K,M,N,P,T for Subset of AP;

theorem Th9:
  AP is Pappian implies AP is satisfying_pap
proof
  assume
A1: AP is Pappian;
    let M,N,a,b,c,a9,b9,c9;
    assume that
A2: M is being_line and
A3: N is being_line and
A4: a in M and
A5: b in M and
A6: c in M and
A7: M // N and
A8: M<>N and
A9: a9 in N and
A10: b9 in N and
A11: c9 in N and
A12: a,b9 // b,a9 and
A13: b,c9 // c,b9;
A14: b<>a9 by A5,A7,A8,A9,AFF_1:45;
    set K=Line(a,c9), C=Line(c,b9);
A15: c <>b9 by A6,A7,A8,A10,AFF_1:45;
    then
A16: C is being_line by AFF_1:24;
    assume
A17: not a,c9 // c,a9;
A18: now
      assume
A19:  a=b;
      then LIN a,b9,a9 by A12,AFF_1:def 1;
      then LIN a9,b9,a by AFF_1:6;
      then a9=b9 or a in N by A3,A9,A10,AFF_1:25;
      hence contradiction by A4,A7,A8,A13,A17,A19,AFF_1:45;
    end;
A20: now
      assume a9=b9;
      then a9,a // a9,b by A12,AFF_1:4;
      then LIN a9,a,b by AFF_1:def 1;
      then LIN a,b,a9 by AFF_1:6;
      then a9 in M by A2,A4,A5,A18,AFF_1:25;
      hence contradiction by A7,A8,A9,AFF_1:45;
    end;
A21: now
      assume
A22:  b=c;
      then LIN b,c9,b9 by A13,AFF_1:def 1;
      then LIN b9,c9,b by AFF_1:6;
      then b9=c9 or b in N by A3,A10,A11,AFF_1:25;
      hence contradiction by A5,A7,A8,A12,A17,A22,AFF_1:45;
    end;
A23: now
      assume b9=c9;
      then b9,b // b9,c by A13,AFF_1:4;
      then LIN b9,b,c by AFF_1:def 1;
      then LIN b,c,b9 by AFF_1:6;
      then b9 in M by A2,A5,A6,A21,AFF_1:25;
      hence contradiction by A7,A8,A10,AFF_1:45;
    end;
A24: a<>c9 by A4,A7,A8,A11,AFF_1:45;
    then
A25: a in K by AFF_1:24;
    K is being_line by A24,AFF_1:24;
    then consider T such that
A26: a9 in T and
A27: K // T by AFF_1:49;
A28: T is being_line by A27,AFF_1:36;
A29: c9 in K by A24,AFF_1:24;
A30: c in C & b9 in C by A15,AFF_1:24;
    not C // T
    proof
      assume C // T;
      then C // K by A27,AFF_1:44;
      then c,b9 // a,c9 by A25,A29,A30,AFF_1:39;
      then b,c9 // a,c9 by A13,A15,AFF_1:5;
      then c9,b // c9,a by AFF_1:4;
      then LIN c9,b,a by AFF_1:def 1;
      then LIN a,b,c9 by AFF_1:6;
      then c9 in M by A2,A4,A5,A18,AFF_1:25;
      hence contradiction by A7,A8,A11,AFF_1:45;
    end;
    then consider x such that
A31: x in C and
A32: x in T by A16,A28,AFF_1:58;
    set D=Line(x,b);
A33: x<>b
    proof
      assume x=b;
      then LIN b,c,b9 by A16,A30,A31,AFF_1:21;
      then b9 in M by A2,A5,A6,A21,AFF_1:25;
      hence contradiction by A7,A8,A10,AFF_1:45;
    end;
    then
A34: b in D by AFF_1:24;
    then
A35: D<>N by A5,A7,A8,AFF_1:45;
A36: D is being_line by A33,AFF_1:24;
A37: x in D by A33,AFF_1:24;
    not D // N
    proof
      assume D // N;
      then D // M by A7,AFF_1:44;
      then x in M by A5,A37,A34,AFF_1:45;
      then c in T or b9 in M by A2,A6,A16,A30,A31,A32,AFF_1:18;
      hence contradiction by A7,A8,A10,A17,A25,A29,A26,A27,AFF_1:39,45;
    end;
    then consider o such that
A38: o in D and
A39: o in N by A3,A36,AFF_1:58;
    LIN b9,c,x by A16,A30,A31,AFF_1:21;
    then
A40: b9,c // b9,x by AFF_1:def 1;
A41: a9<>x
    proof
      assume a9=x;
      then b9,a9 // b9,c by A40,AFF_1:4;
      then LIN b9,a9,c by AFF_1:def 1;
      then c in N by A3,A9,A10,A20,AFF_1:25;
      hence contradiction by A6,A7,A8,AFF_1:45;
    end;
A42: now
      assume o=x;
      then N=T by A3,A9,A26,A28,A32,A39,A41,AFF_1:18;
      then N=K by A11,A29,A27,AFF_1:45;
      hence contradiction by A4,A7,A8,A25,AFF_1:45;
    end;
A43: a,c9 // x,a9 by A25,A29,A26,A27,A32,AFF_1:39;
A44: now
      assume o=a9;
      then LIN a9,b,x by A36,A37,A34,A38,AFF_1:21;
      then a9,b // a9,x by AFF_1:def 1;
      then b,a9 // x,a9 by AFF_1:4;
      then a,b9 // x,a9 by A12,A14,AFF_1:5;
      then a,b9 // a,c9 by A43,A41,AFF_1:5;
      then LIN a,b9,c9 by AFF_1:def 1;
      then LIN b9,c9,a by AFF_1:6;
      then a in N by A3,A10,A11,A23,AFF_1:25;
      hence contradiction by A4,A7,A8,AFF_1:45;
    end;
    c,b9 // x,b9 by A40,AFF_1:4;
    then
A45: b,c9 // x,b9 by A13,A15,AFF_1:5;
A46: a<>b9 by A4,A7,A8,A10,AFF_1:45;
    not a,b9 // D
    proof
      assume a,b9 // D;
      then b,a9 // D by A12,A46,AFF_1:32;
      then a9 in D by A36,A34,AFF_1:23;
      then b in T by A26,A28,A32,A36,A37,A34,A41,AFF_1:18;
      then b,a9 // a,c9 by A25,A29,A26,A27,AFF_1:39;
      then a,b9 // a,c9 by A12,A14,AFF_1:5;
      then LIN a,b9,c9 by AFF_1:def 1;
      then LIN b9,c9,a by AFF_1:6;
      then a in N by A3,A10,A11,A23,AFF_1:25;
      hence contradiction by A4,A7,A8,AFF_1:45;
    end;
    then consider y such that
A47: y in D and
A48: LIN a,b9,y by A36,AFF_1:59;
A49: LIN a,y,a by AFF_1:7;
A50: b9<>x
    proof
      assume b9=x;
      then a,c9 // a9,b9 by A25,A29,A26,A27,A32,AFF_1:39;
      then a,c9 // N by A3,A9,A10,A20,AFF_1:27;
      then c9,a // N by AFF_1:34;
      then a in N by A3,A11,AFF_1:23;
      hence contradiction by A4,A7,A8,AFF_1:45;
    end;
A51: now
      assume o=b9;
      then LIN b9,x,b by A36,A37,A34,A38,AFF_1:21;
      then b9,x // b9,b by AFF_1:def 1;
      then x,b9 // b,b9 by AFF_1:4;
      then b,c9 // b,b9 by A45,A50,AFF_1:5;
      then LIN b,c9,b9 by AFF_1:def 1;
      then LIN b9,c9,b by AFF_1:6;
      then b in N by A3,A10,A11,A23,AFF_1:25;
      hence contradiction by A5,A7,A8,AFF_1:45;
    end;
A52: now
      assume o=y;
      then LIN b9,o,a by A48,AFF_1:6;
      then a in N by A3,A10,A39,A51,AFF_1:25;
      hence contradiction by A4,A7,A8,AFF_1:45;
    end;
A53: b<>c9 by A5,A7,A8,A11,AFF_1:45;
A54: now
      assume o=c9;
      then D // C by A13,A15,A53,A16,A30,A36,A34,A38,AFF_1:38;
      then b in C by A31,A37,A34,AFF_1:45;
      then LIN c,b,b9 by A16,A30,AFF_1:21;
      then b9 in M by A2,A5,A6,A21,AFF_1:25;
      hence contradiction by A7,A8,A10,AFF_1:45;
    end;
    LIN b9,a,y by A48,AFF_1:6;
    then b9,a // b9,y by AFF_1:def 1;
    then a,b9 // y,b9 by AFF_1:4;
    then
A55: y,b9 // b,a9 by A12,A46,AFF_1:5;
    o<>b by A5,A7,A8,A39,AFF_1:45;
    then y,c9 // x,a9 by A1,A3,A9,A10,A11,A36,A37,A34,A38,A39,A45,A47,A55,A35
,A51,A44,A54,A42,A52;
    then y,c9 // a,c9 by A43,A41,AFF_1:5;
    then c9,y // c9,a by AFF_1:4;
    then LIN c9,y,a by AFF_1:def 1;
    then
A56: LIN a,y,c9 by AFF_1:6;
    LIN a,y,b9 by A48,AFF_1:6;
    then a in D or a in N by A3,A10,A11,A23,A47,A56,A49,AFF_1:8,25;
    then D // N by A2,A4,A5,A7,A8,A18,A36,A34,AFF_1:18,45;
    hence contradiction by A38,A39,A35,AFF_1:45;
end;
