reserve n for Nat,
        p,q,u,w for Point of TOP-REAL n,
        S for Subset of TOP-REAL n,
        A, B for convex Subset of TOP-REAL n,
        r for Real;

theorem
 for A be non empty convex Subset of TOP-REAL n st
   A is compact non boundary
 for FR be non empty SubSpace of (TOP-REAL n) |A st [#]FR = Fr A
  holds not FR is_a_retract_of (TOP-REAL n) |A
proof
  set T=TOP-REAL n;
  set cB=cl_Ball(0.T,1),S=Sphere(0.T,1);
A1: [#](T|cB)=cB by PRE_TOPC:def 5;
  then reconsider s=S as Subset of T|cB by TOPREAL9:17;
A2: T|S=T|cB|s by PRE_TOPC:7,TOPREAL9:17;
  let A be non empty convex Subset of T such that
A3: A is compact non boundary;
A4: [#](T|A)=A & Fr A c=A by A3,PRE_TOPC:def 5,TOPS_1:35;
  let FR be non empty SubSpace of T|A such that
A5: [#]FR=Fr A;
  n>0
  proof
   assume n<=0;
   then n=0;
   then {0.T} =the carrier of T by EUCLID:22,77;
   then
A6:  A=[#]T by ZFMISC_1:33;
   then Fr A=Cl A\A by TOPS_1:42;
   hence contradiction by A5,A6,XBOOLE_1:37;
  end;
  then reconsider Ts=T|cB|s as non empty SubSpace of T|cB;
  assume FR is_a_retract_of T|A;
  then consider F be continuous Function of T|A,FR such that
A7: F is being_a_retraction;
  reconsider f=F as Function of T|A,T|A by A5,A4,FUNCT_2:7;
A8: f is continuous by PRE_TOPC:26;
A9: rng F c=Fr A by A5;
  reconsider N=n as Element of NAT by ORDINAL1:def 12;
  set TN=TOP-REAL N;
A10: [#](T|S)=S by PRE_TOPC:def 5;
  T|cB=Tdisk(0.TN,1) & T|S=Tcircle(0.TN,1) by TOPREALB:def 6;
  then
A11: not Ts is_a_retract_of T|cB by A2,Lm6;
  cB is non boundary by Lm5;
  then consider h be Function of T|cB,T|A such that
A12: h is being_homeomorphism and
A13: h.:Fr cB=Fr A by A3,Th7;
A14: dom h=[#](T|cB) by A12,TOPS_2:def 5;
  rng((h")*f)=((h")*f).:dom((h")*f) by RELAT_1:113;
  then
A15: rng((h")*f)c=((h")*f).:dom f by RELAT_1:25,123;
  reconsider H=h as Function;
A16: Fr cB=S by Th5;
 rng h=[#](T|A) by A12,TOPS_2:def 5;
  then
A17: h".:(Fr A) = h"(Fr A) by A12,A4,TOPS_2:55
               .= Fr cB by A12,A13,A1,A14,FUNCT_1:94,TOPS_1:35;
  ((h")*f).:dom f = (h").:(f.:dom f) by RELAT_1:126
                 .= h".:rng f by RELAT_1:113;
  then ((h")*f).:dom f c=Fr cB by A17,A9,RELAT_1:123;
  then rng((h")*f*h)c=rng((h")*f) & rng((h")*f)c=Fr cB
    by A15,RELAT_1:26;
  then rng((h")*f*h)c=Fr cB;
  then reconsider hfh=(h")*f*h as Function of T|cB,Ts by A2,A16,A10,FUNCT_2:6;
  h" is continuous by A12,TOPS_2:def 5;
  then hfh is continuous by A12,A8,PRE_TOPC:27;
  then not hfh is being_a_retraction by A11;
  then consider x be Point of T|cB such that
A18: x in S and
A19: hfh.x<>x by A2,A10;
  set hx=h.x;
A20: dom hfh=the carrier of(T|cB) by FUNCT_2:def 1;
  then
A21: hfh.x=((h")*f).hx by FUNCT_1:12;
  x in dom h by A20,FUNCT_1:11;
  then
A22: hx in the carrier of FR by A5,A13,A16,A18,FUNCT_1:def 6;
  hx in dom((h")*f) by A20,FUNCT_1:11;
  then
A23: ((h")*f).hx=(h").(f.hx) by FUNCT_1:12;
A24: H"=h" by A12,TOPS_2:def 4;
  H".hx=x by A12,A14,FUNCT_1:34;
  hence contradiction by A7,A24,A19,A21,A23,A22;
end;
