reserve i,n,m for Nat,
  x,y,X,Y for set,
  r,s for Real;

theorem Th9:
  for M be non empty MetrSpace for C be sequence of M ex S be
non-empty closed SetSequence of M st S is non-ascending & ( C is Cauchy implies
S is pointwise_bounded & lim diameter S = 0 ) &
for i ex U be Subset of TopSpaceMetr M st
  U = { C.j where j is Nat: j >= i } & S.i = Cl U
proof
  let M be Reflexive symmetric triangle non empty MetrSpace;
  set T=TopSpaceMetr(M);
  let C be sequence of M;
  defpred P[object,object] means
for i st i=$1 ex S be Subset of T st S={C.j where j
  is Nat: j >= i} & $2=Cl S;
A1: for x being object st x in NAT
   ex y being object st y in bool the carrier of M & P[x,y]
  proof
    let x be object;
    assume x in NAT;
    then reconsider x9=x as Nat;
    set S={C.j where j is Nat: j >= x9};
    S c= the carrier of T
    proof
      let y be object;
      assume y in S;
      then ex j be Nat st C.j=y & j>=x9;
      hence thesis;
    end;
    then reconsider S as Subset of T;
    take Cl S;
    thus thesis;
  end;
  consider S be SetSequence of M such that
A2: for x being object st x in NAT holds P[x,S.x] from FUNCT_2:sch 1(A1);
A3: now
    let x be object;
    assume x in dom S;
    then reconsider i=x as Element of NAT;
    consider U be Subset of T such that
A4: U={C.j where j is Nat: j >= i} and
A5: S.i=Cl U by A2;
A6: U c= S.i by A5,PRE_TOPC:18;
    C.i in U by A4;
    hence S.x is non empty by A6;
  end;
  now
    let i;
    i in NAT by ORDINAL1:def 12;
    then
    ex U be Subset of T st U={C.j where j is Nat: j >= i} & S.
    i=Cl U by A2;
    hence S.i is closed by Th6;
  end;
  then reconsider S as non-empty closed SetSequence of M by A3,Def8,
FUNCT_1:def 9;
  take S;
  now
    let i be Nat;
    i in NAT by ORDINAL1:def 12;
    then consider U be Subset of T such that
A7: U={C.j where j is Nat: j >= i} and
A8: S.i=Cl U by A2;
    consider U1 be Subset of T such that
A9: U1={C.j where j is Nat: j >= i+1} and
A10: S.(i+1)=Cl U1 by A2;
    U1 c= U
    proof
      let x be object;
      assume x in U1;
      then consider j be Nat such that
A11:  x=C.j and
A12:  j>=i+1 by A9;
      j>= i by A12,NAT_1:13;
      hence thesis by A7,A11;
    end;
    hence S.(i+1) c= S.i by A8,A10,PRE_TOPC:19;
  end;
  hence
A13: S is non-ascending by KURATO_0:def 3;
  thus C is Cauchy implies S is pointwise_bounded & lim diameter S = 0
  proof
    assume
A14: C is Cauchy;
A15: now
      let i;
      i in NAT by ORDINAL1:def 12;
      then consider U be Subset of T such that
A16:  U={C.j where j is Nat: j >= i} and
A17:  S.i=Cl U by A2;
      reconsider U9=U as Subset of M;
      U c= rng C
      proof
        let x be object;
        assume x in U;
        then consider j be Nat such that
A18:     x=C.j & j>=i by A16;
A19:     j in NAT by ORDINAL1:def 12;
        dom C=NAT by FUNCT_2:def 1;
        hence thesis by A18,FUNCT_1:def 3,A19;
      end;
      then U9 is bounded by A14,TBSP_1:14,26;
      hence S.i is bounded by A17,Th8;
    end;
    then reconsider S9=S as non-empty pointwise_bounded closed SetSequence of M
    by Def1;
    set d=diameter S9;
A20: for r be Real st 0<r ex n be Nat st for m be
    Nat st n<=m holds |.d.m-0 .|<r
    proof
      let r be Real such that
A21:  0<r;
      reconsider R=r as Real;
      set R2=R/2;
      R2>0 by A21,XREAL_1:139;
      then consider p be Nat such that
A22:  for n,m be Nat st p<=n & p<=m holds dist(C.n,C.m)<R2
      by A14;
      take p;
      let m be Nat such that
A23:  p<=m;
      m in NAT by ORDINAL1:def 12;
      then consider U be Subset of T such that
A24:  U={C.j where j is Nat: j >= m} and
A25:  S.m=Cl U by A2;
      reconsider U9=U as Subset of M;
A26:  now
        let x,y being Point of M such that
A27:    x in U9 and
A28:    y in U9;
        consider j be Nat such that
A29:    y=C.j and
A30:    j>=m by A24,A28;
A31:    j>=p by A23,A30,XXREAL_0:2;
        consider i be Nat such that
A32:    x = C.i and
A33:    i>=m by A24,A27;
        i>=p by A23,A33,XXREAL_0:2;
        hence dist(x,y)<=R2 by A22,A32,A29,A31;
      end;
A34:  U c= rng C
      proof
        let x be object;
        assume x in U;
        then consider j be Nat such that
A35:     x=C.j & j>=m by A24;
A36:     j in NAT by ORDINAL1:def 12;
        dom C=NAT by FUNCT_2:def 1;
        hence thesis by A35,FUNCT_1:def 3,A36;
      end;
      then
A37:  U9 is bounded by A14,TBSP_1:14,26;
      then
A38:  diameter U9=diameter S.m by A25,Th8;
      C.m in U by A24;
      then
A39:  diameter U9<=R2 by A37,A26,TBSP_1:def 8;
      rng C is bounded by A14,TBSP_1:26;
      then diameter S.m>=0 by A34,A38,TBSP_1:14,21;
      then
A40:  |.diameter S.m.|<=R2 by A39,A38,ABSVALUE:def 1;
      R2<R by A21,XREAL_1:216;
      then |.diameter S.m.|<R by A40,XXREAL_0:2;
      hence thesis by Def2;
    end;
    thus S is pointwise_bounded by A15;
A41: d is bounded_below by Th1;
    d is non-increasing by A13,Th2;
    hence thesis by A41,A20,SEQ_2:def 7;
  end;
  let i;
  i in NAT by ORDINAL1:def 12;
  hence thesis by A2;
end;
