
theorem Th9:
  for C being FormalContext for O being Subset of the carrier of C
  for A being Subset of the carrier' of C holds O c= (AttributeDerivation(C)).A
  iff [:O,A:] c= the Information of C
proof
  let C be FormalContext;
  let O be Subset of the carrier of C;
  let A be Subset of the carrier' of C;
A1: [:O,A:] c= the Information of C implies O c= (AttributeDerivation(C)).A
  proof
    assume
A2: [:O,A:] c= the Information of C;
    let x be object;
    assume
A3: x in O;
    then reconsider x as Object of C;
    for a being Attribute of C st a in A holds x is-connected-with a
    proof
      let a be Attribute of C;
      consider z being set such that
A4:   z = [x,a];
      assume a in A;
      then z in [:O,A:] by A3,A4,ZFMISC_1:def 2;
      hence thesis by A2,A4;
    end;
    then
    x in {o where o is Object of C : for a being Attribute of C st a in A
    holds o is-connected-with a};
    hence thesis by Def3;
  end;
  O c= (AttributeDerivation(C)).A implies [:O,A:] c= the Information of C
  proof
    assume O c= (AttributeDerivation(C)).A;
    then
A5: O c= {o where o is Object of C : for a being Attribute of C st a in A
    holds o is-connected-with a} by Def3;
    let z be object;
    assume z in [:O,A:];
    then consider x,y being object such that
A6: x in O and
A7: y in A and
A8: z = [x,y] by ZFMISC_1:def 2;
    reconsider y as Attribute of C by A7;
    reconsider x as Object of C by A6;
    x in {o where o is Object of C : for a being Attribute of C st a in A
    holds o is-connected-with a} by A5,A6;
    then
    ex x9 being Object of C st x9 = x & for a being Attribute of C st a in
    A holds x9 is-connected-with a;
    then x is-connected-with y by A7;
    hence thesis by A8;
  end;
  hence thesis by A1;
end;
