reserve A for QC-alphabet;
reserve i,j,k,l,m,n for Nat;
reserve a,b,e for set;
reserve t,u,v,w,z for QC-symbol of A;
reserve p,q,r,s for Element of CQC-WFF(A);
reserve x for Element of bound_QC-variables(A);
reserve ll for CQC-variable_list of k,A;
reserve P for QC-pred_symbol of k,A;

theorem Th9:
  for l being FinSequence holds rng l = { l.i : 1 <= i & i <= len l }
proof
  let l be FinSequence;
  thus rng l c= { l.i : 1 <= i & i <= len l }
  proof
    let a be object;
    assume a in rng l;
    then consider x being object such that
A1: x in dom l and
A2: a = l.x by FUNCT_1:def 3;
    reconsider k = x as Element of NAT by A1;
A3: k <= len l by A1,FINSEQ_3:25;
    1 <= k by A1,FINSEQ_3:25;
    hence thesis by A2,A3;
  end;
  thus { l.i : 1 <= i & i <= len l } c= rng l
  proof
    let a be object;
    assume a in { l.i : 1 <= i & i <= len l };
    then consider k being Nat such that
A4: a = l.k and
A5: 1 <= k and
A6: k <= len l;
    k in dom l by A5,A6,FINSEQ_3:25;
    hence thesis by A4,FUNCT_1:def 3;
  end;
end;
