
theorem Th9:
  for X be non empty set for Y be ComplexNormSpace, f,g,h be
VECTOR of C_VectorSpace_of_BoundedFunctions(X,Y), f9,g9,h9 be bounded Function
of X,the carrier of Y st f9=f & g9=g & h9=h holds (h = f+g iff for x be Element
  of X holds h9.x = f9.x + g9.x )
proof
  let X be non empty set;
  let Y be ComplexNormSpace;
  let f,g,h be VECTOR of C_VectorSpace_of_BoundedFunctions(X,Y);
A1: C_VectorSpace_of_BoundedFunctions(X,Y) is Subspace of ComplexVectSpace(
  X,Y) by Th7,CSSPACE:11;
  then reconsider f1=f as VECTOR of ComplexVectSpace(X,Y) by CLVECT_1:29;
  reconsider h1=h as VECTOR of ComplexVectSpace(X,Y) by A1,CLVECT_1:29;
  reconsider g1=g as VECTOR of ComplexVectSpace(X,Y) by A1,CLVECT_1:29;
  let f9,g9,h9 be bounded Function of X,the carrier of Y such that
A2: f9=f & g9=g & h9=h;
A3: now
    assume
A4: h = f+g;
    let x be Element of X;
    h1=f1+g1 by A1,A4,CLVECT_1:32;
    hence h9.x=f9.x+g9.x by A2,CLOPBAN1:11;
  end;
  now
    assume for x be Element of X holds h9.x=f9.x+g9.x;
    then h1=f1+g1 by A2,CLOPBAN1:11;
    hence h =f+g by A1,CLVECT_1:32;
  end;
  hence thesis by A3;
end;
