reserve D for non empty set,
  i,j,k,l for Nat,
  n for Nat,
  x for set,
  a,b,c,r,r1,r2 for Real,
  p,q for FinSequence of REAL,
  MR,MR1 for Matrix of REAL;

theorem Th9:
  len p >= 1 implies ex q st len q = len p & q.1 = p.1 & (for k st
  0 <> k & k < len p holds q.(k+1) = q.k + p.(k+1)) & Sum p = q.(len p)
proof
  assume
A1: len p >= 1;
  then consider r be Real_Sequence such that
A2: r.1 = p.1 and
A3: for n st 0 <> n & n < len p holds r.(n+1) = r.n + p.(n+1) and
A4: Sum p = r.(len p) by PROB_3:63;
A5: 1 in dom p by A1,FINSEQ_3:25;
  deffunc F(Nat) = r.$1;
  consider q being FinSequence such that
A6: len q = len p & for k be Nat st k in dom q holds q.k = F(k) from
  FINSEQ_1:sch 2;
A7: rng q c= REAL
  proof
    let x be object;
    assume x in rng q;
    then consider j being Nat such that
A8: j in dom q and
A9: q.j = x by FINSEQ_2:10;
    F(j) = q.j by A6,A8;
    hence thesis by A9,XREAL_0:def 1;
  end;
A10: dom q = dom p by A6,FINSEQ_3:29;
  reconsider q as FinSequence of REAL by A7,FINSEQ_1:def 4;
A11: now
    let k such that
A12: 0 <> k and
A13: k < len p;
    k >= 1 by A12,NAT_1:14;
    then
A14: k in dom q by A6,A13,FINSEQ_3:25;
A15: k+1 >= 1 by NAT_1:14;
    k+1 <= len p by A13,NAT_1:13;
    then k+1 in dom q by A6,A15,FINSEQ_3:25;
    hence q.(k+1) = r.(k+1) by A6
      .= r.k + p.(k+1) by A3,A12,A13
      .= q.k + p.(k+1) by A6,A14;
  end;
  take q;
  len p in dom q by A1,A6,FINSEQ_3:25;
  hence thesis by A2,A4,A6,A10,A5,A11;
end;
