reserve h,h1,h2 for 0-convergent non-zero Real_Sequence,
  c,c1 for constant Real_Sequence,
  f,f1,f2 for PartFunc of REAL,REAL,
  x0,r,r0,r1,r2,g,g1,g2 for Real,
  n0,k,n,m for Element of NAT,
  a,b,d for Real_Sequence,
  x for set;

theorem Th9:
 for g being Real holds
  f is_left_differentiable_in x0 & Ldiff(f,x0) = g iff (ex r st 0 <
  r & [.x0 -r,x0.] c= dom f) & for h,c st rng c = {x0} & rng (h+c) c= dom f &
  (for n being Nat holds h.n < 0)
 holds h"(#)(f/*(h+c) - f/*c) is convergent & lim(h"(#)(f/*(h+c) - f/*c)) = g
proof let g be Real;
  thus f is_left_differentiable_in x0 & Ldiff(f,x0) = g implies (ex r st 0 < r
& [.x0 -r,x0.] c= dom f) & for h,c st rng c = {x0} & rng (h+c) c= dom f &
   (for n being Nat holds h.n < 0)
  holds h"(#)(f/*(h+c) - f/*c) is convergent & lim(h"(#)(f/*(h+c
  ) - f/*c)) = g by Def5;
  thus (ex r st 0 <r & [.x0 -r,x0.] c= dom f) & (for h,c st rng c = {x0} & rng
  (h+c) c= dom f & (for n being Nat holds h.n < 0)
   holds h"(#)(f/*(h+c) - f/*c) is
  convergent & lim(h"(#)(f/*(h+c) - f/*c)) = g) implies f
  is_left_differentiable_in x0 & Ldiff(f,x0) = g
  proof
    assume that
A1: ex r st 0 < r & [.x0 -r,x0.] c= dom f and
A2: for h,c st rng c = {x0} & rng (h+c) c= dom f &
  (for n being Nat holds h.n <
0) holds h"(#)(f/*(h+c) - f/*c) is convergent & lim(h"(#) (f/*(h+c) - f/*c)) =
    g;
    for h,c holds rng c = {x0} & rng (h+c) c= dom f &
     (for n being Nat holds h.n < 0
    ) implies h"(#)(f/*(h+c) - f/*c) is convergent by A2;
    hence
A3: f is_left_differentiable_in x0 by A1;
    for h,c holds rng c = {x0} & rng (h+c) c= dom f &
    (for n being Nat holds h.n < 0
    ) implies lim(h"(#)(f/*(h+c) - f/*c)) = g by A2;
    hence thesis by A3,Def5;
  end;
end;
