reserve x,a,b,c for Real,
  n for Nat,
  Z for open Subset of REAL,
  f, f1,f2 for PartFunc of REAL,REAL;

theorem
  not 0 in Z & Z c= dom (cot*((id Z)^)) implies (cot*((id Z)^))
is_differentiable_on Z & for x st x in Z holds ((cot*((id Z)^))`|Z).x = 1/(x^2*
  (sin.(1/x))^2)
proof
  set f = id Z;
  assume that
A1: not 0 in Z and
A2: Z c= dom (cot*(f^));
A3: f^ is_differentiable_on Z by A1,FDIFF_5:4;
  dom (cot*(f^)) c= dom (f^) by RELAT_1:25;
  then
A4: Z c= dom (f^) by A2,XBOOLE_1:1;
A5: for x st x in Z holds (sin.((f^).x))<>0
  proof
    let x;
    assume x in Z;
    then f^.x in dom (cos/sin) by A2,FUNCT_1:11;
    hence thesis by Th2;
  end;
A6: for x st x in Z holds cot*(f^) is_differentiable_in x
  proof
    let x;
    assume
A7: x in Z;
    then (sin.((f^).x))<>0 by A5;
    then
A8: cot is_differentiable_in (f^).x by FDIFF_7:47;
    f^ is_differentiable_in x by A3,A7,FDIFF_1:9;
    hence thesis by A8,FDIFF_2:13;
  end;
  then
A9: cot*(f^) is_differentiable_on Z by A2,FDIFF_1:9;
  for x st x in Z holds ((cot*(f^))`|Z).x = 1/(x^2*(sin.(1/x))^2)
  proof
    let x;
    assume
A10: x in Z;
    then
A11: f^ is_differentiable_in x by A3,FDIFF_1:9;
A12: sin.((f^).x)<>0 by A5,A10;
    then cot is_differentiable_in (f^).x by FDIFF_7:47;
    then diff(cot*(f^),x) = diff(cot,(f^).x)*diff((f^),x) by A11,FDIFF_2:13
      .=(-1/(sin.((f^).x))^2) * diff((f^),x) by A12,FDIFF_7:47
      .=-diff((f^),x)/(sin.((f^).x))^2
      .=-diff((f^),x)/(sin.((f.x)"))^2 by A4,A10,RFUNCT_1:def 2
      .=-diff((f^),x)/(sin.(1*x"))^2 by A10,FUNCT_1:18
      .=-((f^)`|Z).x/(sin.(1*x"))^2 by A3,A10,FDIFF_1:def 7
      .=-(-1/x^2)/(sin.(1*x"))^2 by A1,A10,FDIFF_5:4
      .=-(-1)/x^2/(sin.(1/x))^2
      .=-(-1)/(x^2*(sin.(1/x))^2) by XCMPLX_1:78
      .=1/(x^2*(sin.(1/x))^2);
    hence thesis by A9,A10,FDIFF_1:def 7;
  end;
  hence thesis by A2,A6,FDIFF_1:9;
end;
