 reserve o for object;
 reserve F for non almost_trivial Field;
 reserve x,a for Element of F;

theorem Th9:
   for x being non trivial Element of F, o being object st not o in [#]F
   holds ExField(x,o) is well-unital
   proof
     let x be non trivial Element of F;
     let u be object;
     assume not u in [#]F; then
A1:  for a being Element of F holds a <> u;
     set C = carr(x,u);
     set E = ExField(x,u);
A2:  [#]E = C by Def8;
     now let a be Element of E;
A3:    1.E = 1.F by Def8;
       1.F <> x by Def2; then
       not 1.F in {x} by TARSKI:def 1; then
       1.F in [#]F \ {x} by XBOOLE_0:def 5; then
  reconsider o = 1.F as Element of C by XBOOLE_0:def 3;
A4:    o <> u by A1;
       per cases;
        suppose
A5:       a = u; then
          a in {u} by TARSKI:def 1; then
    reconsider a1 = a as Element of C by XBOOLE_0:def 3;
A6:       (the multF of F).(x,1.F) = x * 1.F .= x;
          thus a * 1.E = (multR(x,u)).(a1,o) by A3,Def8
          .= multR(a1,o) by Def7 .= a by A6,A4,A5,Def6;
A7:       (the multF of F).(1.F,x) = 1.F * x .= x;
          thus 1.E * a = (multR(x,u)).(o,a1) by A3,Def8
          .= multR(o,a1) by Def7 .= a by A7,A4,A5,Def6;
        end;
        suppose
A8:       a <> u; then
          not a in {u} by TARSKI:def 1; then
A9:       a in [#]F \ {x} by A2,XBOOLE_0:def 3;
    reconsider a1 = a as Element of C by Def8;
    reconsider aR = a as Element of [#]F by A9;
A10:      (the multF of F).(a,o) = aR * 1.F .= aR;
A11:      not aR in {x} by A9,XBOOLE_0:def 5; then
A12:      (the multF of F).(a,o) <> x by A10,TARSKI:def 1;
          thus
          a * 1.E = (multR(x,u)).(a1,o) by A3,Def8 .= multR(a1,o) by Def7
          .= aR * 1.F by A12,A4,A8,Def6 .= a;
          (the multF of F).(o,a) = 1.F * aR .= aR; then
A13:      (the multF of F).(o,a) <> x by A11,TARSKI:def 1;
          thus
          1.E * a = (multR(x,u)).(o,a1) by A3,Def8 .= multR(o,a1) by Def7
          .= 1.F * aR by A13,A4,A8,Def6 .= a;
        end;
      end;
      hence ExField(x,u) is well-unital;
    end;
