reserve x,y for set,
  n for Nat;

theorem Th9:
  for f be with_zero non empty FinSequence of NAT,D be
  disjoint_with_NAT set holds Constants(FreeUnivAlgZAO(f,D)) <> {}
proof
  let f be with_zero non empty FinSequence of NAT, D be disjoint_with_NAT set;
  set A = DTConUA(f,D), AA = FreeUnivAlgZAO(f,D);
A1: dom f = Seg len f by FINSEQ_1:def 3;
  set ca = the carrier of AA;
  0 in rng f by Def2;
  then consider n being Nat such that
A2: n in dom f and
A3: f.n = 0 by FINSEQ_2:10;
A4: len FreeOpSeqZAO(f,D) = len f & dom FreeOpSeqZAO(f,D) = Seg len
  FreeOpSeqZAO (f,D) by Def17,FINSEQ_1:def 3;
  then (the charact of AA).n = FreeOpZAO(n,f,D) by A2,A1,Def17;
  then reconsider o = FreeOpZAO(n,f,D) as operation of AA by A2,A4,A1,
FUNCT_1:def 3;
A5: f/.n = f.n & dom(FreeOpZAO(n,f,D)) = (f/.n)-tuples_on (TS A) by A2,Def16,
PARTFUN1:def 6;
  then dom o = {<*>(TS A)} by A3,FINSEQ_2:94;
  then <*>(TS A) in dom o by TARSKI:def 1;
  then
A6: o.(<*>(TS A)) in rng o by FUNCT_1:def 3;
  rng o c= ca by RELAT_1:def 19;
  then reconsider e = o.(<*>(TS A)) as Element of ca by A6;
  dom o = (arity o)-tuples_on (the carrier of AA) by MARGREL1:22;
  then arity o = 0 by A3,A5,FINSEQ_2:110;
  then e in {a where a is Element of ca: ex o be operation of AA st arity o =
  0 & a in rng o} by A6;
  hence thesis;
end;
