reserve i, j, n for Nat,
  f for non constant standard special_circular_sequence,
  g for clockwise_oriented non constant standard special_circular_sequence,
  p, q for Point of TOP-REAL 2,
  P for Subset of TOP-REAL 2,
  C for compact non vertical non horizontal Subset of TOP-REAL 2,
  G for Go-board;

theorem Th9:
  [i,j] in Indices Gauge(C,n) & [i,j+1] in Indices Gauge(C,n)
implies dist(Gauge(C,n)*(i,j),Gauge(C,n)*(i,j+1)) = (N-bound C - S-bound C)/2|^
  n
proof
  set G = Gauge(C,n), a = N-bound C, e = E-bound C, s = S-bound C, w = W-bound
  C, p1 = G*(i,j), p2 = G*(i,j+1);
  assume that
A1: [i,j] in Indices G and
A2: [i,j+1] in Indices G;
A3: p2 = |[w+(e-w)/(2|^n)*(i-2), s+(a-s)/(2|^n)*(j+1-2)]| by A2,JORDAN8:def 1;
  a >= s by SPRECT_1:22;
  then
A4: a - s >= s - s by XREAL_1:9;
  set x = (a-s)/(2|^n);
  consider p, q being Point of Euclid 2 such that
A5: p = p1 & q = p2 and
A6: dist(p1,p2) = dist(p,q) by TOPREAL6:def 1;
A7: p1 = |[w+(e-w)/(2|^n)*(i-2), s+(a-s)/(2|^n)*(j-2)]| by A1,JORDAN8:def 1;
  dist(p,q) = (Pitag_dist 2).(p,q) by METRIC_1:def 1
    .= sqrt ((p1`1 - p2`1)^2 + (p1`2 - p2`2)^2) by A5,TOPREAL3:7
    .= sqrt ((w+(e-w)/(2|^n)*(i-2) - p2`1)^2 + (p1`2 - p2`2)^2) by A7
    .= sqrt ((w+(e-w)/(2|^n)*(i-2) - (w+(e-w)/(2|^n)*(i-2)))^2 + (p1`2 - p2
  `2)^2) by A3
    .= |.p1`2 - p2`2.| by COMPLEX1:72
    .= |.s+x*(j-2) - p2`2.| by A7
    .= |.s+x*(j-2) - (s+x*(j+1-2)).| by A3
    .= |.-x.|
    .= |.x.| by COMPLEX1:52
    .= |.a-s.|/|.2|^n.| by COMPLEX1:67
    .= (a-s)/|.2|^n.| by A4,ABSVALUE:def 1;
  hence thesis by A6,ABSVALUE:def 1;
end;
