reserve i, I for set,
  f, g, h for Function,
  s for ManySortedSet of I;

theorem
  for I being finite set,
      F being associative Group-like multMagma-Family of I holds
    product F = sum F
proof
  let I be finite set, F be associative Group-like multMagma-Family of I;
  set GP = product F, S = sum F;
A1: the carrier of S = the carrier of GP
  proof
    reconsider g = 1_GP as Element of product Carrier F by Def2;
    thus the carrier of S c= the carrier of GP by GROUP_2:def 5;
    let x be object;
    assume x in the carrier of GP;
    then reconsider f = x as Element of product Carrier F by Def2;
A2: for p be Element of product Carrier F holds dom p = I by PARTFUN1:def 2;
    then
A3: dom f = I;
    reconsider f as ManySortedSet of I;
    ex g being Element of product Carrier F, J being finite Subset of I, f
being ManySortedSet of J st g = 1_GP & x = g +* f & for j being set st j in J
ex G being Group-like non empty multMagma st G = F.j & f.j in the carrier of
    G & f.j <> 1_G
    proof
      deffunc F(object) = f.$1;
      defpred P[object] means ex G being Group-like non empty multMagma, m
      being Element of G st G = F.$1 & m = f.$1 & m <> 1_G;
      consider J being set such that
A4:   for j being object holds j in J iff j in I & P[j] from XBOOLE_0:sch
      1;
      J c= I
      by A4;
      then reconsider J as Subset of I;
      consider ff being ManySortedSet of J such that
A5:   for j being object st j in J holds ff.j = F(j) from PBOOLE:sch 4;
A6:   dom ff = J by PARTFUN1:def 2;
A7:   now
        let i be object such that
A8:     i in I;
        per cases;
        suppose
A9:       i in J;
          hence f.i = ff.i by A5
            .= (g +* ff).i by A6,A9,FUNCT_4:13;
        end;
        suppose
A10:      not i in J;
          consider G being Group-like non empty multMagma such that
A11:      G = F.i by A8,Def3;
          f.i is Element of G by A8,A11,Lm1;
          hence f.i = 1_G by A4,A8,A10,A11
            .= g.i by A8,A11,Th6
            .= (g +* ff).i by A6,A10,FUNCT_4:11;
        end;
      end;
      take g, J;
      take ff;
      thus g = 1_GP;
A12:  dom g = I by A2;
      dom (g +* ff) = dom g \/ dom ff by FUNCT_4:def 1
        .= I by A6,A12,XBOOLE_1:12;
      hence x = g +* ff by A3,A7,FUNCT_1:2;
      let j be set;
      assume
A13:  j in J;
      then consider
      G being Group-like non empty multMagma, m being Element of G
      such that
A14:  G = F.j and
A15:  m = f.j and
A16:  m <> 1_G by A4;
      take G;
      ff.j = f.j by A5,A13;
      hence thesis by A14,A15,A16;
    end;
    hence thesis by Def9;
  end;
  product F is Subgroup of product F by GROUP_2:54;
  hence thesis by A1,GROUP_2:59;
end;
