reserve x for Real;
reserve p,q for Point of TOP-REAL 2;

theorem Th9:
  for X being non empty TopSpace, f1,f2 being Function of X,R^1 st
  f1 is continuous & f2 is continuous & (for q being Point of X holds f2.q<>0)
holds ex g being Function of X,R^1 st (for p being Point of X,r1,r2 being Real
 st f1.p=r1 & f2.p=r2 holds g.p=r1/sqrt(1+(r1/r2)^2)) & g is continuous
proof
  let X be non empty TopSpace,f1,f2 be Function of X,R^1;
  assume that
A1: f1 is continuous and
A2: f2 is continuous & for q being Point of X holds f2.q<>0;
  consider g2 being Function of X,R^1 such that
A3: for p being Point of X,r1,r2 being Real st f1.p=r1 & f2.p=r2
  holds g2.p=sqrt(1+(r1/r2)^2) and
A4: g2 is continuous by A1,A2,Th8;
  for q being Point of X holds g2.q<>0
  proof
    let q be Point of X;
    reconsider r1=f1.q,r2=f2.q as Real;
    sqrt(1+(r1/r2)^2)>0 by Lm1,SQUARE_1:25;
    hence thesis by A3;
  end;
  then consider g3 being Function of X,R^1 such that
A5: for p being Point of X,r1,r0 being Real st f1.p=r1 & g2.p=r0
  holds g3.p=r1/r0 and
A6: g3 is continuous by A1,A4,JGRAPH_2:27;
  for p being Point of X,r1,r2 being Real st f1.p=r1 & f2.p=r2
  holds g3.p=r1/sqrt(1+(r1/r2)^2)
  proof
    let p be Point of X,r1,r2 be Real;
    assume that
A7: f1.p=r1 and
A8: f2.p=r2;
    g2.p=sqrt(1+(r1/r2)^2) by A3,A7,A8;
    hence thesis by A5,A7;
  end;
  hence thesis by A6;
end;
