reserve i,j,k,n for Nat,
  X,Y,a,b,c,x for set,
  r,s for Real;
reserve f,g for FinSequence of TOP-REAL 2;

theorem Th9:
  for f1,f2 be FinSequence of TOP-REAL 2 st f1,f2
are_in_general_position for i,j st 1 <= i & i + 1 <= len f1 & 1 <= j & j + 1 <=
  len f2 holds LSeg(f1,i) /\ LSeg(f2,j) is trivial
proof
  let f1,f2 be FinSequence of TOP-REAL 2 such that
A1: f1,f2 are_in_general_position;
  f1 is_in_general_position_wrt f2 by A1;
  then
A2: L~f1 misses rng f2;
  let i,j such that
A3: 1 <= i & i + 1 <= len f1 and
A4: 1 <= j & j + 1 <= len f2;
  f2 is_in_general_position_wrt f1 by A1;
  then
A5: L~f2 misses rng f1;
  now
    set B1 = LSeg(f1/.i,f1/.(i+1)), B2 = LSeg(f2/.j,f2/.(j+1));
    set A1 = LSeg(f1,i), A2 = LSeg(f2,j);
    set A = LSeg(f1,i) /\ LSeg(f2,j);
    assume LSeg(f1,i) /\ LSeg(f2,j) is non trivial;
    then consider a1,a2 being object such that
A6: a1 in A and
A7: a2 in A and
A8: a1 <> a2 by ZFMISC_1:def 10;
A9: a1 in A1 & a2 in A1 by A6,A7,XBOOLE_0:def 4;
A10: a2 in A2 by A7,XBOOLE_0:def 4;
A11: a1 in A2 by A6,XBOOLE_0:def 4;
    reconsider a1, a2 as Point of TOP-REAL 2 by A6,A7;
A12: a2 in B2 by A4,A10,TOPREAL1:def 3;
A13: A1 = B1 by A3,TOPREAL1:def 3;
    then
A14: a2 in B1 by A7,XBOOLE_0:def 4;
    a1 in B2 by A4,A11,TOPREAL1:def 3;
    then
A15: a1 in LSeg(f2/.j,a2) \/ LSeg(a2,f2/.(j+1)) by A12,TOPREAL1:5;
    f1/.i in B1 by RLTOPSP1:68;
    then
A16: LSeg(a2, f1/.i) c= B1 by A14,TOPREAL1:6;
A17: a1 in LSeg(f1/.i,a2) \/ LSeg(a2,f1/.(i+1)) by A9,A13,TOPREAL1:5;
    f2/.j in B2 by RLTOPSP1:68;
    then
A18: LSeg(a2, f2/.j) c= B2 by A12,TOPREAL1:6;
A19: f2/.j in rng f2 by A4,Th3;
A20: f1/.i in rng f1 by A3,Th3;
    f2/.(j+1) in B2 by RLTOPSP1:68;
    then
A21: LSeg(a2,f2/.(j+1)) c= B2 by A12,TOPREAL1:6;
    f1/.(i+1) in B1 by RLTOPSP1:68;
    then
A22: LSeg(a2,f1/.(i+1)) c= B1 by A14,TOPREAL1:6;
A23: f2/.(j+1) in rng f2 by A4,Th3;
A24: f1/.(i+1) in rng f1 by A3,Th3;
    per cases by A17,XBOOLE_0:def 3;
    suppose
A25:  a1 in LSeg(f1/.i,a2);
      now
        per cases by A15,XBOOLE_0:def 3;
        suppose
          a1 in LSeg(f2/.j,a2);
          then f1/.i in LSeg(a2,f2/.j) or f2/.j in LSeg(a2,f1/.i) by A8,A25,
JORDAN4:41;
          then
A26:      f1/.i in B2 or f2/.j in B1 by A18,A16;
          now
            per cases by A3,A4,A26,TOPREAL1:def 3;
            suppose
              f1/.i in A2;
              then f1/.i in L~f2 by SPPOL_2:17;
              hence contradiction by A5,A20,XBOOLE_0:3;
            end;
            suppose
              f2/.j in A1;
              then f2/.j in L~f1 by SPPOL_2:17;
              hence contradiction by A2,A19,XBOOLE_0:3;
            end;
          end;
          hence contradiction;
        end;
        suppose
          a1 in LSeg(a2,f2/.(j+1));
          then f1/.i in LSeg(a2,f2/.(j+1)) or f2/.(j+1) in LSeg(a2,f1/.i) by A8
,A25,JORDAN4:41;
          then
A27:      f1/.i in B2 or f2/.(j+1) in B1 by A16,A21;
          now
            per cases by A3,A4,A27,TOPREAL1:def 3;
            suppose
              f1/.i in A2;
              then f1/.i in L~f2 by SPPOL_2:17;
              hence contradiction by A5,A20,XBOOLE_0:3;
            end;
            suppose
              f2/.(j+1) in A1;
              then f2/.(j+1) in L~f1 by SPPOL_2:17;
              hence contradiction by A2,A23,XBOOLE_0:3;
            end;
          end;
          hence contradiction;
        end;
      end;
      hence contradiction;
    end;
    suppose
A28:  a1 in LSeg(a2,f1/.(i+1));
      now
        per cases by A15,XBOOLE_0:def 3;
        suppose
          a1 in LSeg(f2/.j,a2);
          then f1/.(i+1) in LSeg(a2,f2/.j) or f2/.j in LSeg(a2,f1/.(i+1)) by A8
,A28,JORDAN4:41;
          then
A29:      f1/.(i+1) in B2 or f2/.j in B1 by A18,A22;
          now
            per cases by A3,A4,A29,TOPREAL1:def 3;
            suppose
              f1/.(i+1) in A2;
              then f1/.(i+1) in L~f2 by SPPOL_2:17;
              hence contradiction by A5,A24,XBOOLE_0:3;
            end;
            suppose
              f2/.j in A1;
              then f2/.j in L~f1 by SPPOL_2:17;
              hence contradiction by A2,A19,XBOOLE_0:3;
            end;
          end;
          hence contradiction;
        end;
        suppose
          a1 in LSeg(a2,f2/.(j+1));
          then
          f1/.(i+1) in LSeg(a2,f2/.(j+1)) or f2/.(j+1) in LSeg(a2,f1/.(i+
          1)) by A8,A28,JORDAN4:41;
          then
A30:      f1/.(i+1) in B2 or f2/.(j+1) in B1 by A22,A21;
          now
            per cases by A3,A4,A30,TOPREAL1:def 3;
            suppose
              f1/.(i+1) in A2;
              then f1/.(i+1) in L~f2 by SPPOL_2:17;
              hence contradiction by A5,A24,XBOOLE_0:3;
            end;
            suppose
              f2/.(j+1) in A1;
              then f2/.(j+1) in L~f1 by SPPOL_2:17;
              hence contradiction by A2,A23,XBOOLE_0:3;
            end;
          end;
          hence contradiction;
        end;
      end;
      hence contradiction;
    end;
  end;
  hence thesis;
end;
