reserve C for Simple_closed_curve,
  i, j, n for Nat,
  p for Point of TOP-REAL 2;

theorem Th9:
  for C being compact Subset of TOP-REAL 2 holds BDD C <> {}
  implies N-bound C >= N-bound BDD C
proof
  let C be compact Subset of TOP-REAL 2;
  set WC = N-bound BDD C, WB = N-bound C;
  set hal = (WB + WC)/2;
  assume that
A1: BDD C <> {} and
A2: WC > WB;
A3: hal > WB by A2,XREAL_1:226;
  now
    per cases;
    suppose
      for q1 being Point of TOP-REAL 2 st q1 in BDD C holds q1`2 <= hal;
      hence contradiction by A1,A2,Lm11,XREAL_1:226;
    end;
    suppose
      ex q1 being Point of TOP-REAL 2 st q1 in BDD C & q1`2 > hal;
      then consider q1 being Point of TOP-REAL 2 such that
A4:   q1 in BDD C and
A5:   q1`2 > hal;
      set Q = |[q1`1,(WB + q1`2)/2]|;
      set WH = north_halfline Q;
A6:   Q`2 = (WB + q1`2)/2 by EUCLID:52;
A7:   q1`2 > WB by A3,A5,XXREAL_0:2;
      WH misses C
      proof
A8:     Q`2 > WB by A7,A6,XREAL_1:226;
        assume WH /\ C <> {};
        then consider y being object such that
A9:     y in WH /\ C by XBOOLE_0:def 1;
A10:    y in C by A9,XBOOLE_0:def 4;
A11:    y in WH by A9,XBOOLE_0:def 4;
        reconsider y as Point of TOP-REAL 2 by A9;
        y`2 >= Q`2 by A11,TOPREAL1:def 10;
        then y`2 > WB by A8,XXREAL_0:2;
        hence thesis by A10,PSCOMP_1:24;
      end;
      then
A12:  WH c= UBD C by JORDAN2C:129;
A13:  q1`1 = Q`1 by EUCLID:52;
      q1`2 > Q`2 by A7,A6,XREAL_1:226;
      then q1 in WH by A13,TOPREAL1:def 10;
      then q1 in BDD C /\ UBD C by A4,A12,XBOOLE_0:def 4;
      then BDD C meets UBD C;
      hence contradiction by JORDAN2C:24;
    end;
  end;
  hence thesis;
end;
