reserve i,j,k,m,n for Nat,
  f for FinSequence of the carrier of TOP-REAL 2,
  G for Go-board;

theorem Th9:
  for C being compact non vertical non horizontal Subset of
TOP-REAL 2 for n being Nat holds L~Upper_Seq(C,n) = Upper_Arc L~Cage
  (C,n) & L~Lower_Seq(C,n) = Lower_Arc L~Cage(C,n) or L~Upper_Seq(C,n) =
  Lower_Arc L~Cage(C,n) & L~Lower_Seq(C,n) = Upper_Arc L~Cage(C,n)
proof
  let C be compact non vertical non horizontal Subset of TOP-REAL 2;
  let n be Nat;
  set WC = W-min(L~Cage(C,n));
  set EC = E-max(L~Cage(C,n));
A1: Lower_Arc(L~Cage(C,n)) is_an_arc_of WC,EC & Upper_Arc(L~Cage(C,n)) \/
  Lower_Arc(L~Cage(C,n))=L~Cage(C,n) by JORDAN6:50;
  Upper_Seq(C,n)/.1 = WC & Upper_Seq(C,n)/. len Upper_Seq(C,n) = EC by Th5,Th7;
  then
A2: L~Upper_Seq(C,n) is_an_arc_of WC,EC by TOPREAL1:25;
  Lower_Seq(C,n)/.1 = EC & Lower_Seq(C,n)/. len Lower_Seq(C,n) = WC by Th6,Th8;
  then
A3: L~Lower_Seq(C,n) is_an_arc_of WC,EC by JORDAN5B:14,TOPREAL1:25;
  L~Upper_Seq(C,n) \/ L~Lower_Seq(C,n)=L~Cage(C,n) & Upper_Arc(L~Cage(C,n)
  ) is_an_arc_of WC,EC by JORDAN1E:13,JORDAN6:50;
  hence thesis by A2,A3,A1,JORDAN6:48;
end;
