reserve x,y for set;
reserve s,r for Real;
reserve r1,r2 for Real;
reserve n for Nat;
reserve p,q,q1,q2 for Point of TOP-REAL 2;

theorem Th9:
  for r being Real, P being Subset of TOP-REAL 2
  st P={p where p is Point of TOP-REAL 2: p`2=r} holds P is closed
proof
  let r be Real, P be Subset of TOP-REAL 2;
  assume
A1: P={p where p is Point of TOP-REAL 2: p`2=r};
  defpred P[Point of TOP-REAL 2] means $1`2>=r;
  {p where p is Element of TOP-REAL 2 : P[p]}
  is Subset of TOP-REAL 2 from DOMAIN_1:sch 7;
  then reconsider P1={p where p is Point of TOP-REAL 2: p`2>=r}
  as Subset of TOP-REAL 2;
A2: P1 is closed by Th7;
  defpred Q[Point of TOP-REAL 2] means $1`2<=r;
  {p where p is Element of TOP-REAL 2 : Q[p]}
  is Subset of TOP-REAL 2 from DOMAIN_1:sch 7;
  then reconsider P2={p where p is Point of TOP-REAL 2: p`2<=r}
  as Subset of TOP-REAL 2;
A3: P2 is closed by Th8;
A4: P c= P1 /\ P2
  proof
    let x be object;
    assume x in P;
    then
A5: ex p being Point of TOP-REAL 2 st ( p=x)&( p`2=r) by A1;
    then
A6: x in P1;
    x in P2 by A5;
    hence thesis by A6,XBOOLE_0:def 4;
  end;
  P1 /\ P2 c= P
  proof
    let x be object;
    assume
A7: x in P1 /\ P2;
    then
A8: x in P1 by XBOOLE_0:def 4;
A9: x in P2 by A7,XBOOLE_0:def 4;
    consider q1 being Point of TOP-REAL 2 such that
A10: q1=x and
A11: q1`2>=r by A8;
    ex q2 being Point of TOP-REAL 2 st ( q2=x)&( q2`2<=r) by A9;
    then q1`2=r by A10,A11,XXREAL_0:1;
    hence thesis by A1,A10;
  end;
  then P=P1 /\ P2 by A4;
  hence thesis by A2,A3,TOPS_1:8;
end;
