reserve f,g for PartFunc of REAL,REAL,
  r,r1,r2,g1,g2,g3,g4,g5,g6,x,x0,t,c for Real,
  a,b,s for Real_Sequence,
  n,k for Element of NAT;

theorem
  (ex N being Neighbourhood of x0 st N c= dom f & N c= dom g & f
  is_differentiable_on N & g is_differentiable_on N & N \ {x0} c= dom (f/g) & N
  c= dom ((f`|N)/(g`|N)) & f.x0 = 0 & g.x0 = 0 & (f`|N)/(g`|N) is_convergent_in
x0) implies f/g is_convergent_in x0 & ex N being Neighbourhood of x0 st lim(f/g
  ,x0) = lim(((f`|N)/(g`|N)),x0)
proof
  given N being Neighbourhood of x0 such that
A1: N c= dom f and
A2: N c= dom g and
A3: f is_differentiable_on N and
A4: g is_differentiable_on N and
A5: N \ {x0} c= dom (f/g) and
A6: N c= dom ((f`|N)/(g`|N)) and
A7: f.x0 = 0 & g.x0 = 0 and
A8: (f`|N)/(g`|N) is_convergent_in x0;
  consider r be Real such that
A9: 0<r and
A10: N = ].x0-r,x0+r.[ by RCOMP_1:def 6;
A11: for x st x0<x & x<x0+r ex c st c in ].x0,x.[ & (f/g).x=((f`|N)/(g`|N)). c
  proof
A12: x0-r<x0 by A9,XREAL_1:44;
    x0+0<x0+r by A9,XREAL_1:8;
    then x0 in {g1: x0-r<g1 & g1<x0+r} by A12;
    then
A13: x0 in ].x0-r,x0+r.[ by RCOMP_1:def 2;
A14: dom (f`|N) /\ (dom (g`|N) \ (g`|N)"{0}) c= dom (g`|N)\(g`|N)"{0} by
XBOOLE_1:17;
A15: dom f /\ (dom g\g"{0}) c= dom g\g"{0} by XBOOLE_1:17;
    let x such that
A16: x0<x and
A17: x<x0+r;
    set f1 = (f.x)(#)g - (g.x)(#)f;
A18: dom((f.x)(#)g) = dom g & dom((g.x)(#)f) = dom f by VALUED_1:def 5;
    then
A19: dom((f.x)(#)g - (g.x)(#)f) = dom f /\ dom g by VALUED_1:12;
    x0-r<x by A16,A12,XXREAL_0:2;
    then x in {g1: x0-r<g1 & g1<x0+r} by A17;
    then x in ].x0-r,x0+r.[ by RCOMP_1:def 2;
    then
A20: [.x0,x.] c= N by A10,A13,XXREAL_2:def 12;
    then
A21: [.x0,x.] c= dom f & [.x0,x.] c= dom g by A1,A2;
    then
A22: [.x0,x.] c= dom f1 by A19,XBOOLE_1:19;
    g|N is continuous by A4,FDIFF_1:25;
    then g|[.x0,x.] is continuous by A20,FCONT_1:16;
    then
A23: ((f.x)(#)g)|[.x0,x.] is continuous by A2,A20,FCONT_1:20,XBOOLE_1:1;
    f|N is continuous by A3,FDIFF_1:25;
    then f|[.x0,x.] is continuous by A20,FCONT_1:16;
    then
A24: ((g.x)(#)f)|[.x0,x.] is continuous by A1,A20,FCONT_1:20,XBOOLE_1:1;
    [.x0,x.] c= dom((f.x)(#)g - (g.x)(#)f) by A21,A19,XBOOLE_1:19;
    then
A25: ((f.x)(#)g - (g.x)(#)f)|[.x0,x.] is continuous by A18,A19,A24,A23,
FCONT_1:18;
A26: ].x0,x.[ c= [.x0,x.] by XXREAL_1:25;
    then
A27: ].x0,x.[ c= N by A20;
A28: x in [.x0,x.] by A16,XXREAL_1:1;
    then x in dom f1 by A22;
    then
A29: x in dom ((f.x)(#)g) /\ dom ((g.x) (#)f) by VALUED_1:12;
    then
A30: x in dom ((f.x) (#)g) by XBOOLE_0:def 4;
A31: x0 in [.x0,x.] by A16,XXREAL_1:1;
    then x0 in dom f1 by A22;
    then
A32: x0 in dom ((f.x)(#)g) /\ dom ((g.x)(#)f) by VALUED_1:12;
    then
A33: x0 in dom ((f.x)(#)g) by XBOOLE_0:def 4;
A34: x in dom ((g.x)(#)f) by A29,XBOOLE_0:def 4;
A35: f1.x = ((f.x)(#)g).x - ((g.x)(#)f).x by A22,A28,VALUED_1:13
      .= (f.x)*(g.x) - ((g.x)(#)f).x by A30,VALUED_1:def 5
      .= (g.x)*(f.x) - (g.x)*(f.x) by A34,VALUED_1:def 5
      .= 0;
A36: x0 in dom ((g.x)(#)f) by A32,XBOOLE_0:def 4;
    not x in {x0} by A16,TARSKI:def 1;
    then
A37: x in [.x0,x.]\{x0} by A28,XBOOLE_0:def 5;
    N c= dom ((f.x)(#)g) by A2,VALUED_1:def 5;
    then
A38: ].x0,x.[ c= dom ((f.x)(#)g) by A27;
    N c= dom ((g.x)(#)f) by A1,VALUED_1:def 5;
    then
A39: ].x0,x.[ c= dom ((g.x)(#)f) by A27;
    then ].x0,x.[ c= dom ((f.x)(#)g) /\ dom ((g.x)(#)f) by A38,XBOOLE_1:19;
    then
A40: ].x0,x.[ c= dom ((f.x)(#)g - (g.x)(#)f) by VALUED_1:12;
    f is_differentiable_on ].x0,x.[ by A3,A20,A26,FDIFF_1:26,XBOOLE_1:1;
    then
A41: (g.x)(#)f is_differentiable_on ].x0,x.[ by A39,FDIFF_1:20;
    g is_differentiable_on ].x0,x.[ by A4,A20,A26,FDIFF_1:26,XBOOLE_1:1;
    then
A42: (f.x)(#)g is_differentiable_on ].x0,x.[ by A38,FDIFF_1:20;
    f1.x0 = ((f.x)(#)g).x0 - ((g.x)(#)f).x0 by A22,A31,VALUED_1:13
      .= (f.x)*(g.x0) - ((g.x)(#)f).x0 by A33,VALUED_1:def 5
      .= 0 - (g.x)*0 by A7,A36,VALUED_1:def 5
      .= 0;
    then consider t such that
A43: t in ].x0,x.[ and
A44: diff(f1,t)=0 by A16,A25,A41,A40,A42,A22,A35,FDIFF_1:19,ROLLE:1;
A45: (g.x)(#)f is_differentiable_in t by A41,A43,FDIFF_1:9;
A46: f is_differentiable_in t by A3,A27,A43,FDIFF_1:9;
    (f.x)(#)g is_differentiable_in t by A42,A43,FDIFF_1:9;
    then 0=diff((f.x)(#)g,t) - diff((g.x)(#)f,t) by A44,A45,FDIFF_1:14;
    then
A47: 0=diff((f.x)(#)g,t) - (g.x)*diff(f,t) by A46,FDIFF_1:15;
    take t;
A48: t in [.x0,x.] by A26,A43;
    [.x0,x.]\{x0} c= N\{x0} by A20,XBOOLE_1:33;
    then
A49: [.x0,x.]\{x0} c= dom(f/g) by A5;
    then [.x0,x.]\{x0} c= dom f /\ (dom g\g"{0}) by RFUNCT_1:def 1;
    then [.x0,x.]\{x0} c= dom g\g"{0} by A15;
    then
A50: x in dom g & not x in g"{0} by A37,XBOOLE_0:def 5;
A51: now
      assume g.x=0;
      then g.x in {0} by TARSKI:def 1;
      hence contradiction by A50,FUNCT_1:def 7;
    end;
A52: [.x0,x.] c= dom ((f`|N)/(g`|N)) by A6,A20;
    then [.x0,x.] c= dom (f`|N) /\ (dom (g`|N)\(g`|N)"{0}) by RFUNCT_1:def 1;
    then [.x0,x.] c= dom (g`|N)\(g`|N)"{0} by A14;
    then
A53: t in dom (g`|N) & not t in (g`|N)"{0} by A48,XBOOLE_0:def 5;
A54: now
      assume diff(g,t)=0;
      then (g`|N).t=0 by A4,A20,A48,FDIFF_1:def 7;
      then (g`|N).t in {0} by TARSKI:def 1;
      hence contradiction by A53,FUNCT_1:def 7;
    end;
    g is_differentiable_in t by A4,A27,A43,FDIFF_1:9;
    then 0=(f.x)*diff(g,t) - (g.x)*diff(f,t) by A47,FDIFF_1:15;
    then (f.x)/(g.x) = diff(f,t)/diff(g,t) by A51,A54,XCMPLX_1:94;
    then (f.x)*(g.x)" = diff(f,t)/diff(g,t) by XCMPLX_0:def 9;
    then (f.x)*(g.x)" = diff(f,t)*diff(g,t)" by XCMPLX_0:def 9;
    then (f/g).x = diff(f,t)*diff(g,t)" by A49,A37,RFUNCT_1:def 1;
    then (f/g).x = ((f`|N).t)*diff(g,t)" by A3,A20,A48,FDIFF_1:def 7;
    then (f/g).x = ((f`|N).t)*((g`|N).t)" by A4,A20,A48,FDIFF_1:def 7;
    hence thesis by A43,A52,A48,RFUNCT_1:def 1;
  end;
A55: for a st a is convergent & lim a = x0 & rng a c= dom (f/g) /\
right_open_halfline(x0) holds (f/g)/*a is convergent & lim((f/g)/*a) = lim(((f
  `|N)/(g`|N)),x0)
  proof
    reconsider xx0 = x0 as Element of REAL by XREAL_0:def 1;
    set d = seq_const x0;
    let a;
    assume that
A56: a is convergent and
A57: lim a = x0 and
A58: rng a c= dom (f/g) /\ right_open_halfline(x0);
    consider k such that
A59: for n st k<=n holds x0-r<a.n & a.n<x0+r by A9,A56,A57,LIMFUNC3:7;
    set a1 = a^\k;
    defpred X[Element of NAT,Real] means $2 in ].x0,a1.$1.[ & (((f/g)/*
    a)^\k).$1=((f`|N)/(g`|N)).$2;
A60: now
      let n;
      a.(n+k) in rng a by VALUED_0:28;
      then a.(n+k) in right_open_halfline(x0) by A58,XBOOLE_0:def 4;
      then a.(n+k) in {g1:x0<g1} by XXREAL_1:230;
      then ex g1 st a.(n+k)=g1 & x0<g1;
      hence x0<a1.n by NAT_1:def 3;
      a1.n = a.(n+k) & k<=n+k by NAT_1:12,def 3;
      hence a1.n<x0+r by A59;
    end;
A61: for n ex c be Element of REAL st X[n,c]
    proof
      let n;
A62:  rng a1 c= rng a by VALUED_0:21;
      x0<a1.n & a1.n<x0+r by A60;
      then consider c such that
A63:  c in ].x0,a1.n.[ and
A64:  (f/g).(a1.n)=((f`|N)/(g`|N)).c by A11;
      take c;
A65:  dom (f/g) /\ right_open_halfline(x0) c= dom (f/g) by XBOOLE_1:17;
      then rng a c= dom (f/g) by A58;
      then ((f/g)/*(a^\k)).n=((f`|N)/(g`|N)).c by A64,A62,FUNCT_2:108
,XBOOLE_1:1;
      hence thesis by A58,A63,A65,VALUED_0:27,XBOOLE_1:1;
    end;
    consider b such that
A66: for n holds X[n,b.n] from FUNCT_2:sch 3(A61);
A67: now
      let n be Nat;
A68:    n in NAT by ORDINAL1:def 12;
      b.n in ].x0,a1.n.[ by A66,A68;
      then b.n in {g1:x0<g1 & g1<a1.n} by RCOMP_1:def 2;
      then ex g1 st g1=b.n & x0<g1 & g1<a1.n;
      hence d.n<=b.n & b.n<=a1.n by SEQ_1:57;
    end;
A69: lim d=d.0 by SEQ_4:26
      .=x0 by SEQ_1:57;
    lim a1=x0 by A56,A57,SEQ_4:20;
    then
A70: b is convergent & lim b=x0 by A56,A69,A67,SEQ_2:19,20;
A71: x0-r<x0 by A9,XREAL_1:44;
    x0<x0+r by A9,XREAL_1:29;
    then x0 in {g2: x0-r<g2 & g2<x0+r} by A71;
    then
A72: x0 in ].x0-r,x0+r.[ by RCOMP_1:def 2;
A73: rng b c= dom ((f`|N)/(g`|N)) \{x0}
    proof
      let x be object;
      assume x in rng b;
      then consider n such that
A74:  x=b.n by FUNCT_2:113;
      x0<a1.n by A60;
      then
A75:  x0-r<a1.n by A71,XXREAL_0:2;
      a1.n<x0+r by A60;
      then a1.n in {g3: x0-r<g3 & g3<x0+r} by A75;
      then a1.n in ].x0-r,x0+r.[ by RCOMP_1:def 2;
      then ].x0,a1.n.[ c= [.x0,a1.n.] & [.x0,a1.n.] c= ].x0-r,x0+r.[ by A72,
XXREAL_1:25,XXREAL_2:def 12;
      then ].x0,a1.n.[ c= ].x0-r,x0+r.[;
      then
A76:  ].x0,a1.n.[ c= dom ((f`|N)/(g`|N)) by A6,A10;
A77:  x in ].x0,a1.n.[ by A66,A74;
      then x in {g1:x0<g1 & g1<a1.n} by RCOMP_1:def 2;
      then ex g1 st g1 = x & x0<g1 & g1<a1.n;
      then not x in {x0} by TARSKI:def 1;
      hence thesis by A77,A76,XBOOLE_0:def 5;
    end;
A78: dom ((f`|N)/(g`|N)) \{x0} c= dom ((f`|N)/(g`|N)) by XBOOLE_1:36;
A79: now
      reconsider m = 0 as Nat;
      take m;
      let n be Nat such that
      m <=n;
A80:    n in NAT by ORDINAL1:def 12;
      (((f/g)/*a)^\k).n=((f`|N)/(g`|N)).(b.n) by A66,A80;
      hence (((f/g)/*a)^\k).n = (((f`|N)/(g`|N))/*b).n by A73,A78,FUNCT_2:108
,XBOOLE_1:1,A80;
    end;
    lim(((f`|N)/(g`|N)),x0)=lim(((f`|N)/(g`|N)),x0);
    then
A81: ((f`|N)/(g`|N))/*b is convergent by A8,A70,A73,LIMFUNC3:def 4;
    then
A82: ((f/g)/*a)^\k is convergent by A79,SEQ_4:18;
    lim (((f`|N)/(g`|N))/*b) = lim(((f`|N)/(g`|N)),x0) by A8,A70,A73,
LIMFUNC3:def 4;
    then lim (((f/g)/*a)^\k) = lim(((f`|N)/(g`|N)),x0) by A81,A79,SEQ_4:19;
    hence thesis by A82,SEQ_4:21,22;
  end;
A83: for r1,r2 st r1<x0 & x0<r2 ex g1,g2 st r1<g1 & g1<x0 & g1 in dom (f/g)
  & g2<r2 & x0<g2 & g2 in dom (f/g) by A5,Th4;
  then for r1 st x0<r1 ex t st t<r1 & x0<t & t in dom (f/g) by LIMFUNC3:8;
  then
A84: f/g is_right_convergent_in x0 & lim_right(f/g,x0)=lim(((f`|N)/(g`|N ))
  ,x0) by A55,Th2;
A85: for x st x0-r<x & x<x0 ex c st c in ].x,x0.[ & (f/g).x=((f`|N)/(g`|N)) .c
  proof
A86: x0+0<x0+r by A9,XREAL_1:8;
    x0-r<x0 by A9,XREAL_1:44;
    then x0 in {g1: x0-r<g1 & g1<x0+r} by A86;
    then
A87: x0 in ].x0-r,x0+r.[ by RCOMP_1:def 2;
A88: dom (f`|N) /\ (dom (g`|N) \ (g`|N)"{0}) c= dom (g`|N)\(g`|N)"{0} by
XBOOLE_1:17;
A89: dom f /\ (dom g\g"{0}) c= dom g\g"{0} by XBOOLE_1:17;
    let x such that
A90: x0-r<x and
A91: x<x0;
    set f1 = (f.x)(#)g - (g.x)(#)f;
A92: dom((f.x)(#)g) = dom g & dom((g.x)(#)f) = dom f by VALUED_1:def 5;
    then
A93: dom((f.x)(#)g - (g.x)(#)f) = dom f /\ dom g by VALUED_1:12;
    x<x0+r by A91,A86,XXREAL_0:2;
    then x in {g1: x0-r<g1 & g1<x0+r} by A90;
    then x in ].x0-r,x0+r.[ by RCOMP_1:def 2;
    then
A94: [.x,x0.] c= N by A10,A87,XXREAL_2:def 12;
    then
A95: [.x,x0.] c= dom f & [.x,x0.] c= dom g by A1,A2;
    then
A96: [.x,x0.] c= dom f1 by A93,XBOOLE_1:19;
    g|N is continuous by A4,FDIFF_1:25;
    then g|[.x,x0.] is continuous by A94,FCONT_1:16;
    then
A97: ((f.x)(#)g)|[.x,x0.] is continuous by A2,A94,FCONT_1:20,XBOOLE_1:1;
    f|N is continuous by A3,FDIFF_1:25;
    then f|[.x,x0.] is continuous by A94,FCONT_1:16;
    then
A98: ((g.x)(#)f)|[.x,x0.] is continuous by A1,A94,FCONT_1:20,XBOOLE_1:1;
    [.x,x0.] c= dom((f.x)(#)g - (g.x)(#)f) by A95,A93,XBOOLE_1:19;
    then
A99: ((f.x)(#)g - (g.x)(#)f)|[.x,x0.] is continuous by A92,A93,A98,A97,
FCONT_1:18;
A100: ].x,x0.[ c= [.x,x0.] by XXREAL_1:25;
    then
A101: ].x,x0.[ c= N by A94;
A102: x in [.x,x0.] by A91,XXREAL_1:1;
    then x in dom f1 by A96;
    then
A103: x in dom ((f.x)(#)g) /\ dom ((g.x) (#)f) by VALUED_1:12;
    then
A104: x in dom ((f.x) (#) g) by XBOOLE_0:def 4;
A105: x0 in [.x,x0.] by A91,XXREAL_1:1;
    then x0 in dom f1 by A96;
    then
A106: x0 in dom ((f.x)(#)g) /\ dom ((g.x)(#)f) by VALUED_1:12;
    then
A107: x0 in dom ((f.x)(#)g) by XBOOLE_0:def 4;
A108: x in dom ((g.x)(#)f) by A103,XBOOLE_0:def 4;
A109: f1.x = ((f.x)(#)g).x - ((g.x)(#)f).x by A96,A102,VALUED_1:13
      .= (f.x)*(g.x) - ((g.x)(#)f).x by A104,VALUED_1:def 5
      .= (g.x)*(f.x) - (g.x)*(f.x) by A108,VALUED_1:def 5
      .= 0;
A110: x0 in dom ((g.x)(#)f) by A106,XBOOLE_0:def 4;
    not x in {x0} by A91,TARSKI:def 1;
    then
A111: x in [.x,x0.]\{x0} by A102,XBOOLE_0:def 5;
    N c= dom ((f.x)(#)g) by A2,VALUED_1:def 5;
    then
A112: ].x,x0.[ c= dom ((f.x)(#)g) by A101;
    N c= dom ((g.x)(#)f) by A1,VALUED_1:def 5;
    then
A113: ].x,x0.[ c= dom ((g.x)(#)f) by A101;
    then ].x,x0.[ c= dom ((f.x)(#)g) /\ dom ((g.x)(#)f) by A112,XBOOLE_1:19;
    then
A114: ].x,x0.[ c= dom ((f.x)(#)g - (g.x)(#)f) by VALUED_1:12;
    f is_differentiable_on ].x,x0.[ by A3,A94,A100,FDIFF_1:26,XBOOLE_1:1;
    then
A115: (g.x)(#)f is_differentiable_on ].x,x0.[ by A113,FDIFF_1:20;
    g is_differentiable_on ].x,x0.[ by A4,A94,A100,FDIFF_1:26,XBOOLE_1:1;
    then
A116: (f.x)(#)g is_differentiable_on ].x,x0.[ by A112,FDIFF_1:20;
    f1.x0 = ((f.x)(#)g).x0 - ((g.x)(#)f).x0 by A96,A105,VALUED_1:13
      .= (f.x)*(g.x0) - ((g.x)(#)f).x0 by A107,VALUED_1:def 5
      .= 0 - (g.x)*0 by A7,A110,VALUED_1:def 5
      .= 0;
    then consider t such that
A117: t in ].x,x0.[ and
A118: diff(f1,t)=0 by A91,A99,A115,A114,A116,A96,A109,FDIFF_1:19,ROLLE:1;
A119: (g.x)(#)f is_differentiable_in t by A115,A117,FDIFF_1:9;
A120: f is_differentiable_in t by A3,A101,A117,FDIFF_1:9;
    (f.x)(#)g is_differentiable_in t by A116,A117,FDIFF_1:9;
    then 0=diff((f.x)(#)g,t) - diff((g.x)(#)f,t) by A118,A119,FDIFF_1:14;
    then
A121: 0=diff((f.x)(#)g,t) - (g.x)*diff(f,t) by A120,FDIFF_1:15;
    take t;
A122: t in [.x,x0.] by A100,A117;
    [.x,x0.]\{x0} c= N\{x0} by A94,XBOOLE_1:33;
    then
A123: [.x,x0.]\{x0} c= dom(f/g) by A5;
    then [.x,x0.]\{x0} c= dom f /\ (dom g\g"{0}) by RFUNCT_1:def 1;
    then [.x,x0.]\{x0} c= dom g\g"{0} by A89;
    then
A124: x in dom g & not x in g"{0} by A111,XBOOLE_0:def 5;
A125: now
      assume g.x=0;
      then g.x in {0} by TARSKI:def 1;
      hence contradiction by A124,FUNCT_1:def 7;
    end;
A126: [.x,x0.] c= dom ((f`|N)/(g`|N)) by A6,A94;
    then [.x,x0.] c= dom (f`|N) /\ (dom (g`|N)\(g`|N)"{0}) by RFUNCT_1:def 1;
    then [.x,x0.] c= dom (g`|N)\(g`|N)"{0} by A88;
    then
A127: t in dom (g`|N) & not t in (g`|N)"{0} by A122,XBOOLE_0:def 5;
A128: now
      assume diff(g,t)=0;
      then (g`|N).t=0 by A4,A94,A122,FDIFF_1:def 7;
      then (g`|N).t in {0} by TARSKI:def 1;
      hence contradiction by A127,FUNCT_1:def 7;
    end;
    g is_differentiable_in t by A4,A101,A117,FDIFF_1:9;
    then 0=(f.x)*diff(g,t) - (g.x)*diff(f,t) by A121,FDIFF_1:15;
    then (f.x)/(g.x) = diff(f,t)/diff(g,t) by A125,A128,XCMPLX_1:94;
    then (f.x)*(g.x)" = diff(f,t)/diff(g,t) by XCMPLX_0:def 9;
    then (f.x)*(g.x)" = diff(f,t)*diff(g,t)" by XCMPLX_0:def 9;
    then (f/g).x = diff(f,t)*diff(g,t)" by A123,A111,RFUNCT_1:def 1;
    then (f/g).x = ((f`|N).t)*diff(g,t)" by A3,A94,A122,FDIFF_1:def 7;
    then (f/g).x = ((f`|N).t)*((g`|N).t)" by A4,A94,A122,FDIFF_1:def 7;
    hence thesis by A117,A126,A122,RFUNCT_1:def 1;
  end;
A129: for a st a is convergent & lim a = x0 & rng a c= dom (f/g) /\
left_open_halfline(x0) holds (f/g)/*a is convergent & lim((f/g)/*a) = lim(((f`|
  N)/(g`|N)),x0)
  proof
    reconsider xx0 = x0 as Element of REAL by XREAL_0:def 1;
    set d = seq_const x0;
    let a;
    assume that
A130: a is convergent and
A131: lim a = x0 and
A132: rng a c= dom (f/g) /\ left_open_halfline(x0);
    consider k such that
A133: for n st k<=n holds x0-r<a.n & a.n<x0+r by A9,A130,A131,LIMFUNC3:7;
    set a1 = a^\k;
    defpred X[Element of NAT,Real] means $2 in ].a1.$1,x0.[ & (((f/g)/*
    a)^\k).$1=((f`|N)/(g`|N)).$2;
A134: now
      let n;
      a.(n+k) in rng a by VALUED_0:28;
      then a.(n+k) in left_open_halfline(x0) by A132,XBOOLE_0:def 4;
      then a.(n+k) in {g1:g1<x0} by XXREAL_1:229;
      then ex g1 st a.(n+k)=g1 & g1<x0;
      hence a1.n<x0 by NAT_1:def 3;
      a1.n = a.(n+k) & k<=n+k by NAT_1:12,def 3;
      hence x0-r<a1.n by A133;
    end;
A135: for n ex c be Element of REAL st X[n,c]
    proof
      let n;
A136: rng a1 c= rng a by VALUED_0:21;
      x0-r<a1.n & a1.n<x0 by A134;
      then consider c such that
A137: c in ].a1.n,x0.[ and
A138: (f/g).(a1.n)=((f`|N)/(g`|N)).c by A85;
      take c;
A139: dom (f/g) /\ left_open_halfline(x0) c= dom (f/g) by XBOOLE_1:17;
      then rng a c= dom (f/g) by A132;
      then ((f/g)/*(a^\k)).n=((f`|N)/(g`|N)).c by A138,A136,FUNCT_2:108
,XBOOLE_1:1;
      hence thesis by A132,A137,A139,VALUED_0:27,XBOOLE_1:1;
    end;
    consider b such that
A140: for n holds X[n,b.n] from FUNCT_2:sch 3(A135);
A141: now
      let n be Nat;
A142:    n in NAT by ORDINAL1:def 12;
      b.n in ].a1.n,x0.[ by A140,A142;
      then b.n in {g1:a1.n<g1 & g1<x0} by RCOMP_1:def 2;
      then ex g1 st g1=b.n & a1.n<g1 & g1<x0;
      hence a1.n<=b.n & b.n<= d.n by SEQ_1:57;
    end;
A143: lim d=d.0 by SEQ_4:26
      .=x0 by SEQ_1:57;
    lim a1=x0 by A130,A131,SEQ_4:20;
    then
A144: b is convergent & lim b=x0 by A130,A143,A141,SEQ_2:19,20;
A145: x0<x0+r by A9,XREAL_1:29;
    x0-r<x0 by A9,XREAL_1:44;
    then x0 in {g2: x0-r<g2 & g2<x0+r} by A145;
    then
A146: x0 in ].x0-r,x0+r.[ by RCOMP_1:def 2;
A147: rng b c= dom ((f`|N)/(g`|N)) \{x0}
    proof
      let x be object;
      assume x in rng b;
      then consider n such that
A148: x=b.n by FUNCT_2:113;
      a1.n<x0 by A134;
      then
A149: a1.n<x0+r by A145,XXREAL_0:2;
      x0-r<a1.n by A134;
      then a1.n in {g3: x0-r<g3 & g3<x0+r} by A149;
      then a1.n in ].x0-r,x0+r.[ by RCOMP_1:def 2;
      then ].a1.n,x0.[ c= [.a1.n,x0.] & [.a1.n,x0.] c= ].x0-r,x0+r.[ by A146,
XXREAL_1:25,XXREAL_2:def 12;
      then ].a1.n,x0.[ c= ].x0-r,x0+r.[;
      then
A150: ].a1.n,x0.[ c= dom ((f`|N)/(g`|N)) by A6,A10;
A151: x in ].a1.n,x0.[ by A140,A148;
      then x in {g1:a1.n<g1 & g1<x0} by RCOMP_1:def 2;
      then ex g1 st g1 = x & a1.n<g1 & g1<x0;
      then not x in {x0} by TARSKI:def 1;
      hence thesis by A151,A150,XBOOLE_0:def 5;
    end;
A152: dom ((f`|N)/(g`|N)) \{x0} c= dom ((f`|N)/(g`|N)) by XBOOLE_1:36;
A153: now
      reconsider m = 0 as Nat;
      take m;
      let n be Nat such that
      m <=n;
A154:    n in NAT by ORDINAL1:def 12;
     (((f/g)/*a)^\k).n=((f`|N)/(g`|N)).(b.n) by A140,A154;
      hence (((f/g)/*a)^\k).n = (((f`|N)/(g`|N))/*b).n by A147,A152,FUNCT_2:108
,XBOOLE_1:1, A154;
    end;
    lim(((f`|N)/(g`|N)),x0)=lim(((f`|N)/(g`|N)),x0);
    then
A155: ((f`|N)/(g`|N))/*b is convergent by A8,A144,A147,LIMFUNC3:def 4;
    then
A156: ((f/g)/*a)^\k is convergent by A153,SEQ_4:18;
    lim (((f`|N)/(g`|N))/*b) = lim(((f`|N)/(g`|N)),x0) by A8,A144,A147,
LIMFUNC3:def 4;
    then lim (((f/g)/*a)^\k) = lim(((f`|N)/(g`|N)),x0) by A155,A153,SEQ_4:19;
    hence thesis by A156,SEQ_4:21,22;
  end;
  for r1 st r1<x0 ex t st r1<t & t<x0 & t in dom (f/g) by A83,LIMFUNC3:8;
  then
A157: f/g is_left_convergent_in x0 & lim_left(f/g,x0)=lim(((f`|N)/(g`|N) ),
  x0) by A129,Th3;
  hence f/g is_convergent_in x0 by A84,LIMFUNC3:30;
  take N;
  thus thesis by A84,A157,LIMFUNC3:30;
end;
