reserve M,N for AbGroup;
 reserve R for Ring;
 reserve r for Element of R;

theorem Th9:
   for M,N be LeftMod of R, f be Homomorphism of R,M,N holds
   f is one-to-one onto implies
   f" is Homomorphism of R,N,M
   proof
     let M,N be LeftMod of R, f be Homomorphism of R,M,N;
     assume
A1:  f is one-to-one onto;
     reconsider g = f" as Function of N,M by A1,FUNCT_2:25;
     for a,b being Element of the carrier of N holds g.(a+b) = g.a + g.b
     proof
       let a,b be Element of N;
       consider x being object such that
A2:    x in the carrier of M & a = f.x by A1,FUNCT_2:11;
       reconsider x as Element of M by A2;
       consider y being object such that
A3:    y in the carrier of M & b = f.y by A1,FUNCT_2:11;
       reconsider y as Element of M by A3;
       g.a + g.b = x + g.(f.y) by A1,A2,A3,FUNCT_2:26
                .= x + y by A1,FUNCT_2:26
                .= g.(f.(x+y)) by A1,FUNCT_2:26
                .= g.(a+b) by A2,A3,VECTSP_1:def 20,Def10;
       hence thesis;
     end; then
A4:  g is additive;
     for r be Element of R, a being Element of the carrier of N holds
     g.(r*a) = r*g.a
     proof
       let r be Element of R, a be Element of the carrier of N;
       consider x being object such that
A5:    x in the carrier of M & a = f.x by A1,FUNCT_2:11;
       reconsider x as Element of M by A5;
       g.(r*a) = g.(f.(r*x)) by A5, MOD_2:def 2,Def10
       .= r*x by A1,FUNCT_2:26 .= r*(g.a) by A1,A5,FUNCT_2:26;
       hence thesis;
      end;then
      g is homogeneous;
      hence thesis by A4,Def10;
    end;
