reserve k,t,i,j,m,n for Nat,
  x,y,y1,y2 for object,
  D for non empty set;
reserve K for Field,
  V for VectSp of K,
  a for Element of K,
  W for Element of V;
reserve KL1,KL2,KL3 for Linear_Combination of V,
  X for Subset of V;
reserve s for FinSequence,
  V1,V2,V3 for finite-dimensional VectSp of K,
  f,f1,f2 for Function of V1,V2,
  g for Function of V2,V3,
  b1 for OrdBasis of V1,
  b2 for OrdBasis of V2,
  b3 for OrdBasis of V3,
  v1,v2 for Vector of V2,
  v,w for Element of V1;
reserve p2,F for FinSequence of V1,
  p1,d for FinSequence of K,
  KL for Linear_Combination of V1;

theorem Th9:
  for a being Element of V1 for F being FinSequence of V1 for G
  being FinSequence of K st len F = len G & for k for v being Element of K st k
  in dom F & v = G.k holds F.k = v * a holds Sum(F) = Sum(G) * a
proof
  let a be Element of V1;
  let F be FinSequence of V1;
  let G be FinSequence of K;
  defpred P[Nat] means for H being FinSequence of V1, I being FinSequence of K
st len H = len I & len H = $1 & (for k for v be Element of K st k in dom H & v
  = I.k holds H.k = v * a ) holds Sum(H) = Sum(I) * a;
A1: for n st P[n] holds P[n+1]
  proof
    let n;
    assume
A2: for H being FinSequence of V1, I being FinSequence of K st len H =
    len I & len H = n & (for k for v being Element of K st k in dom H & v = I.k
    holds H.k = v * a) holds Sum(H) = Sum(I) * a;
    let H be FinSequence of V1, I be FinSequence of K;
    assume that
A3: len H = len I and
A4: len H = n + 1 and
A5: for k for v being Element of K st k in dom H & v = I.k holds H.k = v * a;
    reconsider q = I | (Seg n) as FinSequence of K by FINSEQ_1:18;
    reconsider p = H | (Seg n) as FinSequence of V1 by FINSEQ_1:18;
A6: n <= n + 1 by NAT_1:12;
    then
A7: len p = n by A4,FINSEQ_1:17;
A8: dom p = Seg n by A4,A6,FINSEQ_1:17;
A9: len q = n by A3,A4,A6,FINSEQ_1:17;
A10: dom q = Seg n by A3,A4,A6,FINSEQ_1:17;
A11: now
      len p <= len H by A4,A6,FINSEQ_1:17;
      then
A12:  dom p c= dom H by FINSEQ_3:30;
      let k;
      let v be Element of K;
      assume that
A13:  k in dom p and
A14:  v = q.k;
      I.k = q.k by A8,A10,A13,FUNCT_1:47;
      then H.k = v * a by A5,A13,A14,A12;
      hence p.k = v * a by A13,FUNCT_1:47;
    end;
    reconsider n as Element of NAT by ORDINAL1:def 12;
    n + 1 in Seg(n + 1) by FINSEQ_1:4;
    then
A15: n + 1 in dom H by A4,FINSEQ_1:def 3;
    then reconsider v1 = H.(n + 1) as Element of V1 by FINSEQ_2:11;
    dom H = dom I by A3,FINSEQ_3:29;
    then reconsider v2 = I.(n + 1) as Element of K by A15,FINSEQ_2:11;
A16: v1 = v2 * a by A5,A15;
    thus Sum(H) = Sum(p) + v1 by A4,A7,A8,RLVECT_1:38
      .= Sum(q) * a + v2 * a by A2,A7,A9,A11,A16
      .= (Sum(q) + v2) * a by VECTSP_1:def 15
      .= Sum(I) * a by A3,A4,A9,A10,RLVECT_1:38;
  end;
A17: P[0]
  proof
    let H be FinSequence of V1, I be FinSequence of K;
    assume that
A18: len H = len I and
A19: len H = 0 and
    for k for v being Element of K st k in dom H & v = I.k holds H.k = v * a;
    H = <*>(the carrier of V1) by A19;
    then
A20: Sum(H) = 0.V1 by RLVECT_1:43;
    I = <*>(the carrier of K) by A18,A19;
    then Sum(I) = 0.K by RLVECT_1:43;
    hence thesis by A20,VECTSP_1:14;
  end;
  for n holds P[n] from NAT_1:sch 2(A17,A1);
  hence thesis;
end;
