reserve S,T,W,Y for RealNormSpace;
reserve f,f1,f2 for PartFunc of S,T;
reserve Z for Subset of S;
reserve i,n for Nat;

theorem LPB2Th9:
  for X,Y,Z be RealNormSpace
  for f be Element of R_NormSpace_of_BoundedLinearOperators(Y,Z),
    g,h be Element of R_NormSpace_of_BoundedLinearOperators(X,Y)
  holds f * (g + h) = f*g + f*h
  proof
    let X,Y,Z be RealNormSpace;
    let f be Element of R_NormSpace_of_BoundedLinearOperators(Y,Z),
      g,h be Element of R_NormSpace_of_BoundedLinearOperators(X,Y);
    set BLOPXY = R_NormSpace_of_BoundedLinearOperators(X,Y);
    set BLOPXZ = R_NormSpace_of_BoundedLinearOperators(X,Z);
    set mf = modetrans(f,Y,Z);
    set mg = modetrans(g,X,Y);
    set mh = modetrans(h,X,Y);
    set mgh= modetrans(g+h, X,Y);
    A1: mf*mh is Lipschitzian LinearOperator of X,Z by LOPBAN_2:2; then
    reconsider fh=mf*mh as VECTOR of BLOPXZ by LOPBAN_1:def 9;
    A2: mf*mg is Lipschitzian LinearOperator of X,Z by LOPBAN_2:2; then
    reconsider fg=mf*mg as VECTOR of BLOPXZ by LOPBAN_1:def 9;
    A3: mf*mgh is Lipschitzian LinearOperator of X,Z by LOPBAN_2:2; then
    reconsider k=mf*mgh as VECTOR of BLOPXZ by LOPBAN_1:def 9;
    reconsider hh = h as VECTOR of BLOPXY;
    reconsider gg = g as VECTOR of BLOPXY;
    A4: gg = mg & hh = mh by LOPBAN_1:def 11;
    for x be VECTOR of X holds (mf*mgh).x=(mf*mg).x + (mf*mh).x
    proof
      let x be VECTOR of X;
      g+h=gg+hh & modetrans(g+h, X,Y) =g+h by LOPBAN_1:def 11; then
      A5: mgh.x=mg.x+mh.x by A4,LOPBAN_1:35;
      thus (mf*mgh).x = mf.(mgh.x) by A3,LPB2Th4
        .= mf.(mg.x) + mf.(mh.x) by A5,VECTSP_1:def 20
        .= (mf*mg).x + mf.(mh.x) by A2,LPB2Th4
        .= (mf*mg).x + (mf*mh).x by A1,LPB2Th4;
    end;
    hence thesis by LOPBAN_1:35;
  end;
