reserve PM for MetrStruct;
reserve x,y for Element of PM;
reserve r,p,q,s,t for Real;
reserve T for TopSpace;
reserve A for Subset of T;
reserve T for non empty TopSpace;
reserve x for Point of T;
reserve Z,X,V,W,Y,Q for Subset of T;
reserve FX for Subset-Family of T;
reserve a for set;
reserve x,y for Point of T;
reserve A,B for Subset of T;
reserve FX,GX for Subset-Family of T;

theorem Th9:
  FX c= GX & GX is locally_finite implies FX is locally_finite
proof
  assume that
A1: FX c= GX and
A2: GX is locally_finite;
  now
    let x;
    thus ex W being Subset of T st x in W & W is open & { V : V in FX & V
    meets W } is finite
    proof
      consider Y being Subset of T such that
A3:   x in Y and
A4:   Y is open and
A5:   { X : X in GX & X meets Y } is finite by A2;
      take W = Y;
      thus x in W by A3;
      thus W is open by A4;
      { V : V in FX & V meets W } c= { X : X in GX & X meets Y }
      proof
          let Z be object;
          assume
A6:       Z in { V : V in FX & V meets W };
          ex X st Z = X & X in GX & X meets Y
          proof
            consider V such that
A7:         Z = V and
A8:         V in FX and
A9:         V meets W by A6;
            take X = V;
            thus Z = X by A7;
            thus X in GX by A1,A8;
            thus thesis by A9;
          end;
          hence Z in { X : X in GX & X meets Y };
      end;
      hence thesis by A5;
    end;
  end;
  hence thesis;
end;
