reserve n,m,k for Element of NAT,
  x,X for set,
  A1 for SetSequence of X,
  Si for SigmaField of X,
  XSeq for SetSequence of Si;
reserve Omega for non empty set,
  Sigma for SigmaField of Omega,
  ASeq for SetSequence of Sigma,
  P for Probability of Sigma;

theorem Th9:
  for seq being sequence of REAL, Eseq being sequence of
  ExtREAL st seq = Eseq holds Partial_Sums seq = Ser Eseq
proof
  let seq be sequence of REAL, Eseq be sequence of ExtREAL such that
A1: seq = Eseq;
  reconsider Ps = Partial_Sums seq as sequence of  ExtREAL by FUNCT_2:7
,NUMBERS:31;
  defpred P[Nat] means Ps.$1 = (Ser Eseq).$1;
A2: for k being Nat st P[k] holds P[k+1]
  proof
    let k be Nat such that
A3: Ps.k = (Ser Eseq).k;
    reconsider Psk = Ps.k as Real;
    reconsider kk=k as Element of NAT by ORDINAL1:def 12;
    Ps.(k+1) = Psk + seq.(k+1) & (Ser Eseq).(k+1)
     = (Ser Eseq).kk + Eseq.(kk+1) by SERIES_1:def 1,SUPINF_2:def 11;
    hence thesis by A1,A3,SUPINF_2:1;
  end;
  Ps.0 = Eseq.0 by A1,SERIES_1:def 1
    .= (Ser Eseq).0 by SUPINF_2:def 11;
  then
A4: P[0];
  for k being Nat holds P[k] from NAT_1:sch 2(A4,A2);
  hence thesis;
end;
