
theorem Th9:
  for m,k be Nat st k >= 2 holds for r be Tuple of (m+2),k-SD holds
  SDDec(Mmax(r)) + SDDec(DecSD(0,m+2,k)) = SDDec(M0(r)) + SDDec(SDMax(m+2,m,k))
proof
  let m,k be Nat;
  assume that
A1: k >= 2;
  let r be Tuple of (m+2),k-SD;
A2: for i be Nat st i in Seg (m+2) holds DigA(M0(r),i) = DigA(Mmax(r),i) &
DigA(SDMax(m+2,m,k),i) = 0 or DigA(SDMax(m+2,m,k),i) = DigA(Mmax(r),i) & DigA(
  M0(r),i) = 0
  proof
    let i be Nat;
    assume
A3: i in Seg (m+2);
    then
A4: DigA(Mmax(r),i) = MmaxDigit(r,i) by Def4;
A5: i >= 1 by A3,FINSEQ_1:1;
    now
      per cases;
      suppose
A6:     i < m;
A7:     DigA(M0(r),i) = M0Digit(r,i) by A3,Def2
          .= 0 by A3,A6,Def1;
        DigA(Mmax(r),i) = Radix(k) - 1 by A1,A3,A4,A6,Def3
          .= SDMaxDigit(m,k,i) by A1,A5,A6,RADIX_5:def 3
          .= DigA(SDMax(m+2,m,k),i) by A3,RADIX_5:def 4;
        hence thesis by A7;
      end;
      suppose
A8:     i >= m;
A9:     DigA(SDMax(m+2,m,k),i) = SDMaxDigit(m,k,i) by A3,RADIX_5:def 4
          .= 0 by A1,A8,RADIX_5:def 3;
        DigA(Mmax(r),i) = r.i by A1,A3,A4,A8,Def3
          .= M0Digit(r,i) by A3,A8,Def1
          .= DigA(M0(r),i) by A3,Def2;
        hence thesis by A9;
      end;
    end;
    hence thesis;
  end;
  m + 2 >= 1 by NAT_1:12;
  hence thesis by A1,A2,RADIX_5:15;
end;
