reserve x,y for set,
        r,s for Real,
        n for Nat,
        V for RealLinearSpace,
        v,u,w,p for VECTOR of V,
        A,B for Subset of V,
        Af for finite Subset of V,
        I for affinely-independent Subset of V,
        If for finite affinely-independent Subset of V,
        F for Subset-Family of V,
        L1,L2 for Linear_Combination of V;

theorem
  conv A = Int A \/ union{conv (A\{v}) : v in A}
  proof
    set I={conv(A\{v}):v in A};
    hereby let x be object;
      assume x in conv A;
      then x in union{Int B:B c=A} by Th8;
      then consider y such that
      A1: x in y and
      A2: y in {Int B:B c=A} by TARSKI:def 4;
      consider B be Subset of V such that
      A3: y=Int B and
      A4: B c=A by A2;
      per cases;
      suppose A=B;
        hence x in Int A\/union I by A1,A3,XBOOLE_0:def 3;
      end;
      suppose B<>A;
        then B c<A by A4;
        then consider y  being object such that
        A5: y in A and
        A6: not y in B by XBOOLE_0:6;
        reconsider y as Element of V by A5;
        A7: conv(A\{y}) in I by A5;
        B c=A\{y} by A4,A6,ZFMISC_1:34;
        then A8: conv B c=conv(A\{y}) by RLAFFIN1:3;
        x in conv B by A1,A3,Def1;
        then x in union I by A7,A8,TARSKI:def 4;
        hence x in Int A\/union I by XBOOLE_0:def 3;
      end;
    end;
    let x be object;
    A9: now assume x in union I;
          then consider y such that
          A10: x in y and
          A11: y in I by TARSKI:def 4;
          consider v such that
          A12: y=conv(A\{v}) and
          v in A by A11;
          conv(A\{v})c=conv A by RLAFFIN1:3,XBOOLE_1:36;
          hence x in conv A by A10,A12;
    end;
    assume x in Int A\/union I;
    then A13: x in Int A or x in union I by XBOOLE_0:def 3;
    Int A c=conv A by Lm2;
    hence thesis by A9,A13;
  end;
