reserve X1,X2,X3,X4 for set;

theorem Thm11:
  for X,Y being non empty set,
  S being cap-finite-partition-closed Subset-Family of X,
  f being Function of X,Y st f is one-to-one
  holds f.:S is cap-finite-partition-closed Subset-Family of Y
  proof
    let X,Y be non empty set,
    S be cap-finite-partition-closed Subset-Family of X,
    f be Function of X,Y;
    assume
A1: f is one-to-one;
    per cases;
    suppose f.:S is empty;
      hence thesis;
    end;
    suppose
A2:   f.:S is non empty;
      reconsider fS=f.:S as Subset-Family of Y;
      fS is cap-finite-partition-closed
      proof
        let s1,s2 be Element of fS;
        assume
A3:     s1/\s2 is non empty;
A4:     s1 in fS by A2;
        consider c1 be Subset of X such that
A5:     c1 in S and
A6:     s1=f.:c1 by A4,FUNCT_2:def 10;
A7:     s2 in fS by A2;
        consider c2 be Subset of X such that
A8:     c2 in S and
A9:     s2=f.:c2 by A7,FUNCT_2:def 10;
A10:    f.:(c1/\c2) = s1/\s2 by A1,A6,A9,FUNCT_1:62;
        then
A11:    c1/\c2 is non empty by A3;
        consider x1 be finite Subset of S such that
A12:    x1 is a_partition of c1/\c2 by A5,A8,A11,SRINGS_1:def 1;
        x1 c= S & S c= bool X;
        then x1 c= bool X;
        then reconsider x2=x1 as Subset-Family of X;
        now
          thus f.:x2 is finite Subset of fS by FUNCT_2:103;
          thus f.:x2 is a_partition of s1/\s2
          proof
            now
              f.:x2 c= bool (s1/\s2)
              proof
                let t be object;
                assume t in f.:x2;
                then consider y1 be Subset of X such that
A13:            y1 in x2 and
A14:            t = f.:y1 by FUNCT_2:def 10;
                reconsider t1=t as set by A14;
                f.:y1 c= f.:(c1/\c2) by A12,A13,RELAT_1:123;
                then t1 c= (s1/\s2) by A14,A1,A6,A9,FUNCT_1:62;
                hence t in bool (s1/\s2);
              end;
              hence f.:x2 is Subset-Family of s1/\s2;
              now
                hereby
                  let t be object;
                  assume t in union (f.:x2);
                  then consider u be set such that
A15:              t in u and
A16:              u in f.:x2 by TARSKI:def 4;
                  consider v be Subset of X such that
A17:              v in x2 and
A18:              u = f.:v by A16,FUNCT_2:def 10;
                  f.:v c= f.:(c1/\c2) by A12,A17,RELAT_1:123;
                  hence t in s1/\s2 by A15,A18,A10;
                end;
                let t be object;
                assume t in s1/\s2;
                then t in f.:(c1/\c2) by A1,A6,A9,FUNCT_1:62;
                then consider v be object such that
A19:            v in dom f and
A20:            v in c1/\c2 and
A21:            t=f.v by FUNCT_1:def 6;
                v in union x1 by A12,A20,EQREL_1:def 4;
                then consider u be set such that
A22:            v in u and
A23:            u in x1 by TARSKI:def 4;
                reconsider fu=f.:u as Subset of Y;
                f.v in f.:u & f.:u in f.:x2
                  by A19,A22,FUNCT_1:def 6,A23,FUNCT_2:def 10;
                hence t in union (f.:x2) by A21,TARSKI:def 4;
              end;
              hence union (f.:x2) = s1/\s2 by TARSKI:def 3;
              now
                let A be Subset of s1/\s2;
                assume A in f.:x2;
                then consider a0 be Subset of X such that
A26:            a0 in x2 and
A27:            A = f.:a0 by FUNCT_2:def 10;
                thus A <> {}
                proof
                  assume
A28:              A = {};
                  dom f = X by PARTFUN1:def 2;
                  hence contradiction by A26,A12,A28,A27;
                end;
                let B be Subset of s1/\s2;
                assume B in f.:x2;
                then consider b0 be Subset of X such that
A29:              b0 in x2 and
A30:              B = f.:b0 by FUNCT_2:def 10;
                thus A=B or A misses B
                by A26,A29,A12,EQREL_1:def 4,A27,A30,A1,FUNCT_1:66;
              end;
              hence for A be Subset of s1/\s2 st A in f.:x2 holds
              A <> {} &
              for B be Subset of s1/\s2 st B in f.:x2 holds
              A=B or A misses B;
            end;
            hence thesis by EQREL_1:def 4;
          end;
        end;
        hence ex x be finite Subset of fS st x is a_partition of s1/\s2;
      end;
      hence thesis;
    end;
  end;
