reserve M for non empty MetrSpace,
  c,g1,g2 for Element of M;
reserve N for non empty MetrStruct,
  w for Element of N,
  G for Subset-Family of N,
  C for Subset of N;
reserve R for Reflexive non empty MetrStruct;
reserve T for Reflexive symmetric triangle non empty MetrStruct,
  t1 for Element of T,
  Y for Subset-Family of T,
  P for Subset of T;
reserve f for Function,
  n,m,p,n1,n2,k for Nat,
  r,s,L for Real,
  x,y for set;
reserve S1 for sequence of M,
  S2 for sequence of N;

theorem
  N is Reflexive triangle & TopSpaceMetr(N) is compact implies N is
  totally_bounded
proof
  assume
A1: N is Reflexive;
  set TM = TopSpaceMetr(N);
  assume
A2: N is triangle;
  assume
A3: TopSpaceMetr(N) is compact;
  let r such that
A4: r>0;
  defpred X[Subset of N] means ex x being Element of N st $1 = Ball(x,r);
  consider G being Subset-Family of N such that
A5: for C holds C in G iff X[C] from SUBSET_1:sch 3;
A6: TM = TopStruct (# the carrier of N,Family_open_set(N) #) by PCOMPS_1:def 5;
  then reconsider G as Subset-Family of TopSpaceMetr(N);
  for x being Element of TM holds x in union G
  proof
    let x be Element of TM;
    reconsider x as Element of N by A6;
    dist(x,x)=0 by A1,METRIC_1:1;
    then
A7: x in Ball(x,r) by A4,METRIC_1:11;
    Ball(x,r) in G by A5;
    hence thesis by A7,TARSKI:def 4;
  end;
  then [#](TM) = union G by SUBSET_1:28;
  then
A8: G is Cover of TM by SETFAM_1:45;
  for C being Subset of TopSpaceMetr(N) st C in G holds C is open
  proof
    let C be Subset of TopSpaceMetr(N) such that
A9: C in G;
    reconsider C as Subset of N by A6;
    ex x being Element of N st C = Ball(x,r) by A5,A9;
    then C in the topology of TM by A2,A6,PCOMPS_1:29;
    hence thesis by PRE_TOPC:def 2;
  end;
  then G is open by TOPS_2:def 1;
  then consider H being Subset-Family of TM such that
A10: H c= G and
A11: H is Cover of TM and
A12: H is finite by A3,A8,COMPTS_1:def 1;
  reconsider H as Subset-Family of N by A6;
  take H;
  union H = the carrier of TM by A11,SETFAM_1:45;
  hence thesis by A6,A5,A10,A12;
end;
