reserve r for Real;
reserve a, b for Real;
reserve T for non empty TopSpace;
reserve A for non empty SubSpace of T;
reserve P,Q for Subset of T,
  p for Point of T;
reserve M for non empty MetrSpace,
  p for Point of M;
reserve A for non empty SubSpace of M;

theorem Th9:
  for r being Real for M being MetrSpace, A being SubSpace
  of M for x being Point of M, x9 being Point of A st x = x9 holds Ball(x9,r) =
  Ball(x,r) /\ the carrier of A
proof
  let r be Real;
  let M be MetrSpace, A be SubSpace of M;
  let x be Point of M, x9 be Point of A;
  assume
A1: x = x9;
  now
    let a be object;
    assume
A2: a in Ball(x9,r);
    then reconsider y9 = a as Point of A;
    the carrier of A c= the carrier of M by Def1;
    then
A3: M is non empty by A2;
    A is non empty by A2;
    then reconsider y = y9 as Point of M by A3,Th8;
    dist(x9,y9) < r by A2,METRIC_1:11;
    then (the distance of A).(x9,y9) < r;
    then (the distance of M).(x,y) < r by A1,Def1;
    then dist(x,y) < r;
    then a in Ball(x,r) by A3,METRIC_1:11;
    hence a in Ball(x,r) /\ the carrier of A by A2,XBOOLE_0:def 4;
  end;
  then
A4: Ball(x9,r) c= Ball(x,r) /\ the carrier of A;
  now
    let a be object;
    assume
A5: a in Ball(x,r) /\ the carrier of A;
    then reconsider y9 = a as Point of A by XBOOLE_0:def 4;
    reconsider y = y9 as Point of M by A5;
    a in Ball(x,r) by A5,XBOOLE_0:def 4;
    then dist(x,y) < r by METRIC_1:11;
    then (the distance of M).(x,y) < r;
    then (the distance of A).(x9,y9) < r by A1,Def1;
    then
A6: dist(x9,y9) < r;
    the carrier of A is non empty by A5;
    then A is non empty;
    hence a in Ball(x9,r) by A6,METRIC_1:11;
  end;
  then Ball(x,r) /\ the carrier of A c= Ball(x9,r);
  hence thesis by A4,XBOOLE_0:def 10;
end;
