reserve p,p1,p2,p3,p11,p22,q,q1,q2 for Point of TOP-REAL 2,
  f,h for FinSequence of TOP-REAL 2,
  r,r1,r2,s,s1,s2 for Real,
  u,u1,u2,u5 for Point of Euclid 2,
  n,m,i,j,k for Nat,
  N for Nat,
  x,y,z for set;
reserve lambda for Real;

theorem Th9:
  r1 <= s1 implies {p1: p1`1=r & r1<=p1`2 & p1`2<=s1} = LSeg(|[r,
  r1]|,|[r,s1]|)
proof
  set L = { p3 : p3`1 = r & r1 <= p3`2 & p3`2 <= s1}, p = |[ r,r1 ]|, q = |[ r
  ,s1 ]|;
A1: p`1 = r;
  assume
A2: r1 <= s1;
  then
A3: s1 - r1 >= r1 - r1 by XREAL_1:13;
A4: q`2 = s1;
A6: q`1 = r;
  thus L c= LSeg(p,q)
  proof
    per cases by A2,XXREAL_0:1;
    suppose
A7:   r1 = s1;
      L c= {p}
      proof
        let x be object;
        assume x in L;
        then consider p2 such that
A8:     x = p2 and
A9:     p2`1 = r and
A10:    r1 <= p2`2 & p2`2 <= s1;
        p`2 = p2`2 by A7,A10,XXREAL_0:1;
        then p2 = p by A1,A9,Th6;
        hence thesis by A8,TARSKI:def 1;
      end;
      hence thesis by A7,RLTOPSP1:70;
    end;
    suppose
A11:  r1 < s1;
      let x be object;
      assume x in L;
      then consider p2 such that
A12:  x = p2 and
A13:  p2`1 = r and
A14:  r1 <= p2`2 and
A15:  p2`2 <= s1;
      set t = p2`2, l = (t - r1)/(s1-r1);
A16:  s1 - r1 > 0 by A11,XREAL_1:50;
      then
A17:  1-l = (1*(s1-r1) -(t-r1))/(s1-r1) by XCMPLX_1:127
        .= (s1 - t)/(s1-r1);
      t - r1 <= s1 - r1 by A15,XREAL_1:9;
      then l <= (s1-r1)/(s1-r1) by A16,XREAL_1:72;
      then
A18:  l <= 1 by A16,XCMPLX_1:60;
A19:  ((1-l)*p + l*q)`1 = ((1-l)*p)`1 + (l*q)`1 by Th2
        .= (1-l)* (p`1) + (l*q)`1 by Th4
        .= (1-l)*r + l*r by A6,Th4
        .= p2`1 by A13;
      ((1-l)*p + l*q)`2 = ((1-l)*p)`2 + (l*q)`2 by Th2
        .= (1-l)* (p`2) + (l*q)`2 by Th4
        .= (1-l)*(p`2) + l*(q`2) by Th4
        .= (s1-t)*(p`2)/(s1-r1) + l*(q`2) by A17,XCMPLX_1:74
        .= (s1-t)*(p`2)/(s1-r1) + (t-r1)*(q`2)/(s1-r1) by XCMPLX_1:74
        .= (s1 * r1 - t*r1 + (t-r1)*s1)/(s1-r1) by XCMPLX_1:62
        .= t*(s1 - r1)/(s1-r1)
        .= t*((s1 - r1)/(s1-r1)) by XCMPLX_1:74
        .= t*1 by A16,XCMPLX_1:60
        .= p2`2;
      then
A20:  p2 = (1-l)*p + l*q by A19,Th6;
      r1 - r1 <= t - r1 by A14,XREAL_1:9;
      hence thesis by A16,A12,A18,A20;
    end;
  end;
  let x be object;
  assume x in LSeg(p,q);
  then consider lambda such that
A21: (1-lambda)*p + lambda*q = x and
A22: 0 <= lambda and
A23: lambda <= 1;
A24: r1+0<=r1+lambda*(s1-r1) by A3,A22,XREAL_1:7;
  lambda*(s1-r1)<= 1*(s1-r1) by A3,A23,XREAL_1:64;
  then
A25: r1+lambda*(s1-r1)<=s1-r1+r1 by XREAL_1:7;
  set p2 = (1-lambda)*p + lambda*q;
A26: p2 `2 = ((1-lambda)*p)`2 + (lambda*q)`2 by Th2
    .= (1-lambda)*(p`2) + (lambda*q)`2 by Th4
    .= 1*r1-lambda*r1 + lambda*s1 by A4,Th4
    .= r1+lambda*(s1 - r1);
  p2 `1 = ((1-lambda)*p)`1 + (lambda*q)`1 by Th2
    .= (1-lambda)*(p`1) + (lambda*q)`1 by Th4
    .= (1-lambda)*r + lambda*r by A6,Th4
    .= 1*r;
  hence thesis by A21,A26,A24,A25;
end;
