reserve GF for Field,
  V for VectSp of GF,
  W for Subspace of V,
  x, y, y1, y2 for set,
  i, n, m for Nat;

theorem Th9:
  for L being Linear_Combination of V st Carrier(L) c= the carrier
of W holds ex K being Linear_Combination of W st Carrier(K) = Carrier(L) & Sum(
  K) = Sum (L)
proof
  let L be Linear_Combination of V;
  assume
A1: Carrier(L) c= the carrier of W;
  then reconsider C = Carrier(L) as finite Subset of W;
  the carrier of W c= the carrier of V by VECTSP_4:def 2;
  then reconsider K = L|the carrier of W as Function of the carrier of W, the
  carrier of GF by FUNCT_2:32;
A2: K is Element of Funcs(the carrier of W, the carrier of GF) by FUNCT_2:8;
A3: dom K = the carrier of W by FUNCT_2:def 1;
  now
    let w be Vector of W;
A4: w is Vector of V by VECTSP_4:10;
    assume not w in C;
    then L.w = 0.GF by A4,VECTSP_6:2;
    hence K.w = 0.GF by A3,FUNCT_1:47;
  end;
  then reconsider K as Linear_Combination of W by A2,VECTSP_6:def 1;
  take K;
  thus thesis by A1,Th7;
end;
