reserve x for set;

theorem Th9:
  for L being LATTICE holds
  (ex K being full Sublattice of L st N_5,K are_isomorphic) iff
  ex a,b,c,d,e being Element of L st
  a,b,c,d,e are_mutually_distinct &
  a"/\"b = a & a"/\"c = a & c"/\"e = c & d"/\"e = d & b"/\"c = a & b"/\"d = b &
  c"/\"d = a & b"\/"c = e & c"\/"d = e
proof
  set cn = the carrier of N_5;
  let L be LATTICE;
A1: cn = {0, 3 \ 1, 2, 3 \ 2, 3} by YELLOW_1:1;
  thus (ex K being full Sublattice of L st N_5,K are_isomorphic) implies ex a,
b,c,d,e being Element of L st a,b,c,d,e are_mutually_distinct &
a"/\"b = a & a"/\"c = a & c"/\"e = c & d"/\"e = d & b
  "/\"c = a & b"/\"d = b & c"/\"d = a & b"\/"c = e & c"\/"d = e
  proof
    reconsider td = 3\2 as Element of N_5 by A1,ENUMSET1:def 3;
    reconsider dw = 2 as Element of N_5 by A1,ENUMSET1:def 3;
    reconsider t = 3 as Element of N_5 by A1,ENUMSET1:def 3;
    reconsider tj = 3\1 as Element of N_5 by A1,ENUMSET1:def 3;
    reconsider cl = the carrier of L as non empty set;
    reconsider z = 0 as Element of N_5 by A1,ENUMSET1:def 3;
    given K being full Sublattice of L such that
A2: N_5,K are_isomorphic;
    consider f being Function of N_5,K such that
A3: f is isomorphic by A2;
A4: K is non empty by A3,WAYBEL_0:def 38;
    then
A5: f is one-to-one monotone by A3,WAYBEL_0:def 38;
    reconsider K as non empty SubRelStr of L by A3,WAYBEL_0:def 38;
    reconsider ck = the carrier of K as non empty set;
A6: ck = rng f by A3,WAYBEL_0:66;
    reconsider g=f as Function of cn,ck;
    reconsider a=g.z,b=g.td,c =g.dw,d=g.tj,e=g.t as Element of K;
    reconsider ck as non empty Subset of cl by YELLOW_0:def 13;
A7: b in ck;
A8: c in ck;
A9: e in ck;
A10: d in ck;
    a in ck;
    then reconsider A=a,B=b,C=c,D=d,E=e as Element of L by A7,A8,A10,A9;
    take A,B,C,D,E;
    thus A<>B by A5,Th4,WAYBEL_1:def 1;
    thus A<>C by A5,WAYBEL_1:def 1;
    thus A<>D by A5,Th3,WAYBEL_1:def 1;
    thus A<>E by A5,WAYBEL_1:def 1;
    now
      assume f.td = f.dw;
      then
A11:  td = dw by A4,A5,WAYBEL_1:def 1;
      2 in td by Th4,TARSKI:def 1;
      hence contradiction by A11;
    end;
    hence B<>C;
    now
A12:  1 in tj by Th3,TARSKI:def 2;
      assume
A13:  f.td = f.tj;
      not 1 in td by Th4,TARSKI:def 1;
      hence contradiction by A4,A5,A13,A12,WAYBEL_1:def 1;
    end;
    hence B<>D;
    now
A14:  1 in t by CARD_1:51,ENUMSET1:def 1;
      assume
A15:  f.td = f.t;
      not 1 in td by Th4,TARSKI:def 1;
      hence contradiction by A4,A5,A15,A14,WAYBEL_1:def 1;
    end;
    hence B<>E;
    now
      assume f.dw = f.tj;
      then
A16:  dw = tj by A4,A5,WAYBEL_1:def 1;
      2 in tj by Th3,TARSKI:def 2;
      hence contradiction by A16;
    end;
    hence C<>D;
    thus C<>E by A5,WAYBEL_1:def 1;
    now
A17:  0 in t by CARD_1:51,ENUMSET1:def 1;
      assume
A18:  f.tj = f.t;
      not 0 in tj by Th3,TARSKI:def 2;
      hence contradiction by A4,A5,A18,A17,WAYBEL_1:def 1;
    end;
    hence D<>E;
    z c= td;
    then z <= td by YELLOW_1:3;
    then a <= b by A3,WAYBEL_0:66;
    then A <= B by YELLOW_0:59;
    hence A "/\" B = A by YELLOW_0:25;
    z c= dw;
    then z <= dw by YELLOW_1:3;
    then a <= c by A3,WAYBEL_0:66;
    then A <= C by YELLOW_0:59;
    hence A "/\" C = A by YELLOW_0:25;
    Segm 2 c= Segm 3 by NAT_1:39;
    then dw <= t by YELLOW_1:3;
    then c <= e by A3,WAYBEL_0:66;
    then C <= E by YELLOW_0:59;
    hence C"/\"E = C by YELLOW_0:25;
    tj <= t by YELLOW_1:3;
    then d <= e by A3,WAYBEL_0:66;
    then D <= E by YELLOW_0:59;
    hence D"/\"E = D by YELLOW_0:25;
    thus B"/\"C = A
    proof
A19:  now
        assume B"/\"C = D;
        then D <= C by YELLOW_0:23;
        then d <= c by YELLOW_0:60;
        then tj <= dw by A3,WAYBEL_0:66;
        then
A20:    tj c= dw by YELLOW_1:3;
        2 in tj by Th3,TARSKI:def 2;
        then 2 in 2 by A20;
        hence contradiction;
      end;
A21:  now
        assume B"/\"C = E;
        then E <= C by YELLOW_0:23;
        then e <= c by YELLOW_0:60;
        then t <= dw by A3,WAYBEL_0:66;
        then
A22:    t c= dw by YELLOW_1:3;
        2 in t by CARD_1:51,ENUMSET1:def 1;
        then 2 in 2 by A22;
        hence contradiction;
      end;
A23:  now
        assume B"/\"C = B;
        then B <= C by YELLOW_0:25;
        then b <= c by YELLOW_0:60;
        then td <= dw by A3,WAYBEL_0:66;
        then
A24:    td c= dw by YELLOW_1:3;
        2 in td by Th4,TARSKI:def 1;
        then 2 in 2 by A24;
        hence contradiction;
      end;
A25:  now
        assume B"/\"C = C;
        then C <= B by YELLOW_0:25;
        then c <= b by YELLOW_0:60;
        then dw <= td by A3,WAYBEL_0:66;
        then
A26:    dw c= td by YELLOW_1:3;
        0 in dw by CARD_1:50,TARSKI:def 2;
        hence contradiction by A26,Th4,TARSKI:def 1;
      end;
      ex_inf_of {B,C},L by YELLOW_0:21;
      then inf{B,C} in the carrier of K by YELLOW_0:def 16;
      then B"/\"C in rng f by A6,YELLOW_0:40;
      then ex x being object st x in dom f & B"/\"C = f.x by FUNCT_1:def 3;
      hence thesis by A1,A23,A25,A19,A21,ENUMSET1:def 3;
    end;
    td <= tj by Lm1,YELLOW_1:3;
    then b <= d by A3,WAYBEL_0:66;
    then B <= D by YELLOW_0:59;
    hence B"/\"D = B by YELLOW_0:25;
    thus C"/\"D = A
    proof
A27:  now
        assume C"/\"D = D;
        then D <= C by YELLOW_0:23;
        then d <= c by YELLOW_0:60;
        then tj <= dw by A3,WAYBEL_0:66;
        then
A28:    tj c= dw by YELLOW_1:3;
        2 in tj by Th3,TARSKI:def 2;
        then 2 in 2 by A28;
        hence contradiction;
      end;
A29:  now
        assume C"/\"D = E;
        then E <= C by YELLOW_0:23;
        then e <= c by YELLOW_0:60;
        then t <= dw by A3,WAYBEL_0:66;
        then
A30:    t c= dw by YELLOW_1:3;
        2 in t by CARD_1:51,ENUMSET1:def 1;
        then 2 in 2 by A30;
        hence contradiction;
      end;
A31:  now
        assume C"/\"D = B;
        then B <= C by YELLOW_0:23;
        then b <= c by YELLOW_0:60;
        then td <= dw by A3,WAYBEL_0:66;
        then
A32:    td c= dw by YELLOW_1:3;
        2 in td by Th4,TARSKI:def 1;
        then 2 in 2 by A32;
        hence contradiction;
      end;
A33:  now
        assume C"/\"D = C;
        then C <= D by YELLOW_0:25;
        then c <= d by YELLOW_0:60;
        then dw <= tj by A3,WAYBEL_0:66;
        then
A34:    dw c= tj by YELLOW_1:3;
        0 in dw by CARD_1:50,TARSKI:def 2;
        hence contradiction by A34,Th3,TARSKI:def 2;
      end;
      ex_inf_of {C,D},L by YELLOW_0:21;
      then inf{C,D} in the carrier of K by YELLOW_0:def 16;
      then C"/\"D in rng f by A6,YELLOW_0:40;
      then ex x being object st x in dom f & C"/\"D = f.x by FUNCT_1:def 3;
      hence thesis by A1,A31,A33,A27,A29,ENUMSET1:def 3;
    end;
    thus B"\/"C = E
    proof
A35:  now
        assume B"\/"C = C;
        then C >= B by YELLOW_0:24;
        then c >= b by YELLOW_0:60;
        then dw >= td by A3,WAYBEL_0:66;
        then
A36:    td c= dw by YELLOW_1:3;
        2 in td by Th4,TARSKI:def 1;
        then 2 in 2 by A36;
        hence contradiction;
      end;
A37:  now
        assume B"\/"C = D;
        then D >= C by YELLOW_0:22;
        then d >= c by YELLOW_0:60;
        then tj >= dw by A3,WAYBEL_0:66;
        then
A38:    dw c= tj by YELLOW_1:3;
        0 in dw by CARD_1:50,TARSKI:def 2;
        hence contradiction by A38,Th3,TARSKI:def 2;
      end;
A39:  now
        assume B"\/"C = B;
        then B >= C by YELLOW_0:24;
        then b >= c by YELLOW_0:60;
        then td >= dw by A3,WAYBEL_0:66;
        then
A40:    dw c= td by YELLOW_1:3;
        0 in dw by CARD_1:50,TARSKI:def 2;
        hence contradiction by A40,Th4,TARSKI:def 1;
      end;
A41:  now
        assume B"\/"C = A;
        then A >= C by YELLOW_0:22;
        then a >= c by YELLOW_0:60;
        then z >= dw by A3,WAYBEL_0:66;
        then dw c= z by YELLOW_1:3;
        hence contradiction;
      end;
      ex_sup_of {B,C},L by YELLOW_0:20;
      then sup{B,C} in the carrier of K by YELLOW_0:def 17;
      then B"\/"C in rng f by A6,YELLOW_0:41;
      then ex x being object st x in dom f & B"\/"C = f.x by FUNCT_1:def 3;
      hence thesis by A1,A39,A35,A37,A41,ENUMSET1:def 3;
    end;
    thus C"\/"D = E
    proof
A42:  now
        assume C"\/"D = D;
        then D >= C by YELLOW_0:22;
        then d >= c by YELLOW_0:60;
        then tj >= dw by A3,WAYBEL_0:66;
        then
A43:    dw c= tj by YELLOW_1:3;
        0 in dw by CARD_1:50,TARSKI:def 2;
        hence contradiction by A43,Th3,TARSKI:def 2;
      end;
A44:  now
        assume C"\/"D = C;
        then C >= D by YELLOW_0:24;
        then c >= d by YELLOW_0:60;
        then dw >= tj by A3,WAYBEL_0:66;
        then
A45:    tj c= dw by YELLOW_1:3;
        2 in tj by Th3,TARSKI:def 2;
        hence contradiction by A45,CARD_1:50,TARSKI:def 2;
      end;
A46:  now
        assume C"\/"D = B;
        then B >= C by YELLOW_0:22;
        then b >= c by YELLOW_0:60;
        then td >= dw by A3,WAYBEL_0:66;
        then
A47:    dw c= td by YELLOW_1:3;
        0 in dw by CARD_1:50,TARSKI:def 2;
        hence contradiction by A47,Th4,TARSKI:def 1;
      end;
A48:  now
        assume C"\/"D = A;
        then A >= C by YELLOW_0:22;
        then a >= c by YELLOW_0:60;
        then z >= dw by A3,WAYBEL_0:66;
        then dw c= z by YELLOW_1:3;
        hence contradiction;
      end;
      ex_sup_of {C,D},L by YELLOW_0:20;
      then sup{C,D} in the carrier of K by YELLOW_0:def 17;
      then C"\/"D in rng f by A6,YELLOW_0:41;
      then ex x being object st x in dom f & C"\/"D = f.x by FUNCT_1:def 3;
      hence thesis by A1,A46,A44,A42,A48,ENUMSET1:def 3;
    end;
  end;
  thus (ex a,b,c,d,e being Element of L st (a,b,c,d,e are_mutually_distinct &
  a"/\"b = a & a"/\"c = a & c"/\"e = c & d
  "/\"e = d & b"/\"c = a & b"/\"d = b & c"/\"d = a & b"\/"c = e & c"\/"d = e))
  implies ex K being full Sublattice of L st N_5,K are_isomorphic
  proof
    given a,b,c,d,e being Element of L such that
AAA: a,b,c,d,e are_mutually_distinct and
A59: a"/\"b = a and
A60: a"/\"c = a and
A61: c"/\"e = c and
A62: d"/\"e = d and
A63: b"/\"c = a and
A64: b"/\"d = b and
A65: c"/\"d = a and
A66: b"\/"c = e and
A67: c"\/"d = e;
    set ck = {a,b,c,d,e};
    reconsider ck as Subset of L;
    set K = subrelstr ck;
A68: the carrier of K = ck by YELLOW_0:def 15;
A69: K is meet-inheriting
    proof
      let x,y be Element of L;
      assume that
A70:  x in the carrier of K and
A71:  y in the carrier of K and
      ex_inf_of {x,y},L;
      per cases by A68,A70,A71,ENUMSET1:def 3;
      suppose
        x=a & y=a;
        then inf{x,y} = a"/\"a by YELLOW_0:40;
        then inf{x,y} = a by YELLOW_5:2;
        hence thesis by A68,ENUMSET1:def 3;
      end;
      suppose
        x=a & y=b;
        then inf{x,y} = a"/\"b by YELLOW_0:40;
        hence thesis by A59,A68,ENUMSET1:def 3;
      end;
      suppose
        x=a & y=c;
        then inf{x,y} = a"/\"c by YELLOW_0:40;
        hence thesis by A60,A68,ENUMSET1:def 3;
      end;
      suppose
A72:    x=a & y=d;
A73:    b <= d by A64,YELLOW_0:25;
        a <= b by A59,YELLOW_0:25;
        then a <= d by A73,ORDERS_2:3;
        then a"/\"d = a by YELLOW_0:25;
        then inf {x,y} = a by A72,YELLOW_0:40;
        hence thesis by A68,ENUMSET1:def 3;
      end;
      suppose
A74:    x=a & y=e;
A75:    c <= e by A61,YELLOW_0:25;
        a <= c by A60,YELLOW_0:25;
        then a <= e by A75,ORDERS_2:3;
        then a"/\"e = a by YELLOW_0:25;
        then inf {x,y} = a by A74,YELLOW_0:40;
        hence thesis by A68,ENUMSET1:def 3;
      end;
      suppose
        x=b & y=a;
        then inf{x,y} = a"/\"b by YELLOW_0:40;
        hence thesis by A59,A68,ENUMSET1:def 3;
      end;
      suppose
        x=b & y=b;
        then inf{x,y} = b"/\"b by YELLOW_0:40;
        then inf{x,y} = b by YELLOW_5:2;
        hence thesis by A68,ENUMSET1:def 3;
      end;
      suppose
        x=b & y=c;
        then inf{x,y} = b"/\"c by YELLOW_0:40;
        hence thesis by A63,A68,ENUMSET1:def 3;
      end;
      suppose
        x=b & y=d;
        then inf{x,y} = b"/\"d by YELLOW_0:40;
        hence thesis by A64,A68,ENUMSET1:def 3;
      end;
      suppose
A76:    x=b & y=e;
A77:    d <= e by A62,YELLOW_0:25;
        b <= d by A64,YELLOW_0:25;
        then b <= e by A77,ORDERS_2:3;
        then b"/\"e = b by YELLOW_0:25;
        then inf {x,y} = b by A76,YELLOW_0:40;
        hence thesis by A68,ENUMSET1:def 3;
      end;
      suppose
        x=c & y=a;
        then inf{x,y} = a"/\"c by YELLOW_0:40;
        hence thesis by A60,A68,ENUMSET1:def 3;
      end;
      suppose
        x=c & y=b;
        then inf{x,y} = b"/\"c by YELLOW_0:40;
        hence thesis by A63,A68,ENUMSET1:def 3;
      end;
      suppose
        x=c & y=c;
        then inf{x,y} = c"/\"c by YELLOW_0:40;
        then inf{x,y} = c by YELLOW_5:2;
        hence thesis by A68,ENUMSET1:def 3;
      end;
      suppose
        x=c & y=d;
        then inf{x,y} = c"/\"d by YELLOW_0:40;
        hence thesis by A65,A68,ENUMSET1:def 3;
      end;
      suppose
        x=c & y=e;
        then inf{x,y} = c"/\"e by YELLOW_0:40;
        hence thesis by A61,A68,ENUMSET1:def 3;
      end;
      suppose
A78:    x=d & y=a;
A79:    b <= d by A64,YELLOW_0:25;
        a <= b by A59,YELLOW_0:25;
        then a <= d by A79,ORDERS_2:3;
        then a"/\"d = a by YELLOW_0:25;
        then inf {x,y} = a by A78,YELLOW_0:40;
        hence thesis by A68,ENUMSET1:def 3;
      end;
      suppose
        x=d & y=b;
        then inf{x,y} = b"/\"d by YELLOW_0:40;
        hence thesis by A64,A68,ENUMSET1:def 3;
      end;
      suppose
        x=d & y=c;
        then inf{x,y} = c"/\"d by YELLOW_0:40;
        hence thesis by A65,A68,ENUMSET1:def 3;
      end;
      suppose
        x=d & y=d;
        then inf{x,y} = d"/\"d by YELLOW_0:40;
        then inf{x,y} = d by YELLOW_5:2;
        hence thesis by A68,ENUMSET1:def 3;
      end;
      suppose
        x=d & y=e;
        then inf{x,y} = d"/\"e by YELLOW_0:40;
        hence thesis by A62,A68,ENUMSET1:def 3;
      end;
      suppose
A80:    x=e & y=a;
A81:    c <= e by A61,YELLOW_0:25;
        a <= c by A60,YELLOW_0:25;
        then a <= e by A81,ORDERS_2:3;
        then a"/\"e = a by YELLOW_0:25;
        then inf {x,y} = a by A80,YELLOW_0:40;
        hence thesis by A68,ENUMSET1:def 3;
      end;
      suppose
A82:    x=e & y=b;
A83:    d <= e by A62,YELLOW_0:25;
        b <= d by A64,YELLOW_0:25;
        then b <= e by A83,ORDERS_2:3;
        then b"/\"e = b by YELLOW_0:25;
        then inf {x,y} = b by A82,YELLOW_0:40;
        hence thesis by A68,ENUMSET1:def 3;
      end;
      suppose
        x=e & y=c;
        then inf{x,y} = c"/\"e by YELLOW_0:40;
        hence thesis by A61,A68,ENUMSET1:def 3;
      end;
      suppose
        x=e & y=d;
        then inf{x,y} = d"/\"e by YELLOW_0:40;
        hence thesis by A62,A68,ENUMSET1:def 3;
      end;
      suppose
        x=e & y=e;
        then inf{x,y} = e"/\"e by YELLOW_0:40;
        then inf{x,y} = e by YELLOW_5:2;
        hence thesis by A68,ENUMSET1:def 3;
      end;
    end;
    K is join-inheriting
    proof
      let x,y be Element of L;
      assume that
A84:  x in the carrier of K and
A85:  y in the carrier of K and
      ex_sup_of {x,y},L;
      per cases by A68,A84,A85,ENUMSET1:def 3;
      suppose
        x=a & y=a;
        then sup{x,y} = a"\/"a by YELLOW_0:41;
        then sup{x,y} = a by YELLOW_5:1;
        hence thesis by A68,ENUMSET1:def 3;
      end;
      suppose
        x=a & y=b;
        then x"\/"y = b by A59,Th5;
        then sup{x,y} = b by YELLOW_0:41;
        hence thesis by A68,ENUMSET1:def 3;
      end;
      suppose
        x=a & y=c;
        then x"\/"y = c by A60,Th5;
        then sup{x,y} = c by YELLOW_0:41;
        hence thesis by A68,ENUMSET1:def 3;
      end;
      suppose
A86:    x=a & y=d;
A87:    b <= d by A64,YELLOW_0:25;
        a <= b by A59,YELLOW_0:25;
        then a <= d by A87,ORDERS_2:3;
        then a"/\"d = a by YELLOW_0:25;
        then a"\/"d = d by Th5;
        then sup {x,y} = d by A86,YELLOW_0:41;
        hence thesis by A68,ENUMSET1:def 3;
      end;
      suppose
A88:    x=a & y=e;
A89:    c <= e by A61,YELLOW_0:25;
        a <= c by A60,YELLOW_0:25;
        then a <= e by A89,ORDERS_2:3;
        then a"/\"e = a by YELLOW_0:25;
        then a"\/"e = e by Th5;
        then sup {x,y} = e by A88,YELLOW_0:41;
        hence thesis by A68,ENUMSET1:def 3;
      end;
      suppose
A90:    x=b & y=a;
        a"\/"b = b by A59,Th5;
        then sup{x,y} = b by A90,YELLOW_0:41;
        hence thesis by A68,ENUMSET1:def 3;
      end;
      suppose
        x=b & y=b;
        then sup{x,y} = b"\/"b by YELLOW_0:41;
        then sup{x,y} = b by YELLOW_5:1;
        hence thesis by A68,ENUMSET1:def 3;
      end;
      suppose
        x=b & y=c;
        then sup{x,y} = b"\/"c by YELLOW_0:41;
        hence thesis by A66,A68,ENUMSET1:def 3;
      end;
      suppose
A91:    x=b & y=d;
        b"\/"d = d by A64,Th5;
        then sup{x,y} = d by A91,YELLOW_0:41;
        hence thesis by A68,ENUMSET1:def 3;
      end;
      suppose
A92:    x=b & y=e;
A93:    d <= e by A62,YELLOW_0:25;
        b <= d by A64,YELLOW_0:25;
        then b <= e by A93,ORDERS_2:3;
        then b"/\"e = b by YELLOW_0:25;
        then b"\/"e = e by Th5;
        then sup {x,y} = e by A92,YELLOW_0:41;
        hence thesis by A68,ENUMSET1:def 3;
      end;
      suppose
A94:    x=c & y=a;
        c"\/"a = c by A60,Th5;
        then sup{x,y} = c by A94,YELLOW_0:41;
        hence thesis by A68,ENUMSET1:def 3;
      end;
      suppose
        x=c & y=b;
        then sup{x,y} = b"\/"c by YELLOW_0:41;
        hence thesis by A66,A68,ENUMSET1:def 3;
      end;
      suppose
        x=c & y=c;
        then sup{x,y} = c"\/"c by YELLOW_0:41;
        then sup{x,y} = c by YELLOW_5:1;
        hence thesis by A68,ENUMSET1:def 3;
      end;
      suppose
        x=c & y=d;
        then sup{x,y} = c"\/"d by YELLOW_0:41;
        hence thesis by A67,A68,ENUMSET1:def 3;
      end;
      suppose
A95:    x=c & y=e;
        c"\/"e = e by A61,Th5;
        then sup{x,y} = e by A95,YELLOW_0:41;
        hence thesis by A68,ENUMSET1:def 3;
      end;
      suppose
A96:    x=d & y=a;
A97:    b <= d by A64,YELLOW_0:25;
        a <= b by A59,YELLOW_0:25;
        then a <= d by A97,ORDERS_2:3;
        then a"/\"d = a by YELLOW_0:25;
        then a"\/"d = d by Th5;
        then sup {x,y} = d by A96,YELLOW_0:41;
        hence thesis by A68,ENUMSET1:def 3;
      end;
      suppose
A98:    x=d & y=b;
        b"\/"d = d by A64,Th5;
        then sup{x,y} = d by A98,YELLOW_0:41;
        hence thesis by A68,ENUMSET1:def 3;
      end;
      suppose
        x=d & y=c;
        then sup{x,y} = c"\/"d by YELLOW_0:41;
        hence thesis by A67,A68,ENUMSET1:def 3;
      end;
      suppose
        x=d & y=d;
        then sup{x,y} = d"\/"d by YELLOW_0:41;
        then sup{x,y} = d by YELLOW_5:1;
        hence thesis by A68,ENUMSET1:def 3;
      end;
      suppose
A99:    x=d & y=e;
        d"\/"e = e by A62,Th5;
        then sup{x,y} = e by A99,YELLOW_0:41;
        hence thesis by A68,ENUMSET1:def 3;
      end;
      suppose
A100:   x=e & y=a;
A101:   c <= e by A61,YELLOW_0:25;
        a <= c by A60,YELLOW_0:25;
        then a <= e by A101,ORDERS_2:3;
        then a"/\"e = a by YELLOW_0:25;
        then a"\/"e = e by Th5;
        then sup {x,y} = e by A100,YELLOW_0:41;
        hence thesis by A68,ENUMSET1:def 3;
      end;
      suppose
A102:   x=e & y=b;
A103:   d <= e by A62,YELLOW_0:25;
        b <= d by A64,YELLOW_0:25;
        then b <= e by A103,ORDERS_2:3;
        then b"/\"e = b by YELLOW_0:25;
        then b"\/"e = e by Th5;
        then sup {x,y} = e by A102,YELLOW_0:41;
        hence thesis by A68,ENUMSET1:def 3;
      end;
      suppose
A104:   x=e & y=c;
        c"\/"e = e by A61,Th5;
        then sup{x,y} = e by A104,YELLOW_0:41;
        hence thesis by A68,ENUMSET1:def 3;
      end;
      suppose
A105:   x=e & y=d;
        d"\/"e = e by A62,Th5;
        then sup{x,y} = e by A105,YELLOW_0:41;
        hence thesis by A68,ENUMSET1:def 3;
      end;
      suppose
        x=e & y=e;
        then sup{x,y} = e"\/"e by YELLOW_0:41;
        then sup{x,y} = e by YELLOW_5:1;
        hence thesis by A68,ENUMSET1:def 3;
      end;
    end;
    then reconsider K as non empty full Sublattice of L by A69,YELLOW_0:def 15;
    take K;
    thus N_5,K are_isomorphic
    proof
      reconsider t = 3 as Element of N_5 by A1,ENUMSET1:def 3;
      reconsider td = 3\2 as Element of N_5 by A1,ENUMSET1:def 3;
      reconsider dw = 2 as Element of N_5 by A1,ENUMSET1:def 3;
A106: now
        assume
A107:   dw=td;
        2 in td by Th4,TARSKI:def 1;
        hence contradiction by A107;
      end;
A108: now
        assume
A109:   td=t;
        not 1 in td by Th4,TARSKI:def 1;
        hence contradiction by A109,CARD_1:51,ENUMSET1:def 1;
      end;
      reconsider tj = 3\1 as Element of N_5 by A1,ENUMSET1:def 3;
      reconsider z = 0 as Element of N_5 by A1,ENUMSET1:def 3;
      defpred P[object,object] means
for X being Element of N_5 st X=$1 holds ((X =
z implies $2 = a) & (X = td implies $2 = b) & (X = dw implies $2 = c) & (X = tj
      implies $2 = d) & (X = t implies $2 = e));
A110: now
        assume
A111:   tj=dw;
        2 in tj by Th3,TARSKI:def 2;
        hence contradiction by A111;
      end;
A112: now
        assume
A113:   tj=t;
        not 0 in tj by Th3,TARSKI:def 2;
        hence contradiction by A113,CARD_1:51,ENUMSET1:def 1;
      end;
A114: now
        assume
A115:   tj=td;
        not 1 in td by Th4,TARSKI:def 1;
        hence contradiction by A115,Th3,TARSKI:def 2;
      end;
A116: for x being object st x in cn ex y being object st y in ck & P[x,y]
      proof
        let x be object;
        assume
A117:   x in cn;
        per cases by A1,A117,ENUMSET1:def 3;
        suppose
A118:     x = 0;
          take y=a;
          thus y in ck by ENUMSET1:def 3;
          let X be Element of N_5;
          thus thesis by A118,Th3,Th4;
        end;
        suppose
A119:     x=3\1;
          take y=d;
          thus y in ck by ENUMSET1:def 3;
          let X be Element of N_5;
          thus thesis by A110,A114,A112,A119,Th3;
        end;
        suppose
A120:     x = 2;
          take y=c;
          thus y in ck by ENUMSET1:def 3;
          let X be Element of N_5;
          thus thesis by A110,A106,A120;
        end;
        suppose
A121:     x = 3 \ 2;
          take y=b;
          thus y in ck by ENUMSET1:def 3;
          let X be Element of N_5;
          thus thesis by A114,A106,A108,A121,Th4;
        end;
        suppose
A122:     x = 3;
          take y=e;
          thus y in ck by ENUMSET1:def 3;
          let X be Element of N_5;
          thus thesis by A112,A108,A122;
        end;
      end;
      consider f being Function of cn,ck such that
A123: for x being object st x in cn holds P[x,f.x] from FUNCT_2:sch 1(
      A116);
      reconsider f as Function of N_5,K by A68;
A124: now
        let x,y be Element of N_5;
        assume
A125:   f.x = f.y;
        thus x=y
        proof
          per cases by A1,ENUMSET1:def 3;
          suppose
            x = z & y = z;
            hence thesis;
          end;
          suppose
            x = tj & y = tj;
            hence thesis;
          end;
          suppose
            x = td & y = td;
            hence thesis;
          end;
          suppose
            x = dw & y = dw;
            hence thesis;
          end;
          suppose
            x = t & y = t;
            hence thesis;
          end;
          suppose
A126:       x = z & y = tj;
            then f.x=a by A123;
            hence thesis by AAA,A123,A125,A126;
          end;
          suppose
A127:       x = z & y = dw;
            then f.x=a by A123;
            hence thesis by AAA,A123,A125,A127;
          end;
          suppose
A128:       x = z & y = td;
            then f.x=a by A123;
            hence thesis by AAA,A123,A125,A128;
          end;
          suppose
A129:       x = z & y = t;
            then f.x=a by A123;
            hence thesis by AAA,A123,A125,A129;
          end;
          suppose
A130:       x = tj & y = z;
            then f.x=d by A123;
            hence thesis by AAA,A123,A125,A130;
          end;
          suppose
A131:       x = tj & y = dw;
            then f.x=d by A123;
            hence thesis by AAA,A123,A125,A131;
          end;
          suppose
A132:       x = tj & y = td;
            then f.x=d by A123;
            hence thesis by AAA,A123,A125,A132;
          end;
          suppose
A133:       x = tj & y = t;
            then f.x=d by A123;
            hence thesis by AAA,A123,A125,A133;
          end;
          suppose
A134:       x = dw & y = z;
            then f.x=c by A123;
            hence thesis by AAA,A123,A125,A134;
          end;
          suppose
A135:       x = dw & y = tj;
            then f.x=c by A123;
            hence thesis by AAA,A123,A125,A135;
          end;
          suppose
A136:       x = dw & y = td;
            then f.x=c by A123;
            hence thesis by AAA,A123,A125,A136;
          end;
          suppose
A137:       x = dw & y = t;
            then f.x=c by A123;
            hence thesis by AAA,A123,A125,A137;
          end;
          suppose
A138:       x = td & y = z;
            then f.x=b by A123;
            hence thesis by AAA,A123,A125,A138;
          end;
          suppose
A139:       x = td & y = tj;
            then f.x=b by A123;
            hence thesis by AAA,A123,A125,A139;
          end;
          suppose
A140:       x = td & y = dw;
            then f.x=b by A123;
            hence thesis by AAA,A123,A125,A140;
          end;
          suppose
A141:       x = td & y = t;
            then f.x=b by A123;
            hence thesis by AAA,A123,A125,A141;
          end;
          suppose
A142:       x = t & y = z;
            then f.x=e by A123;
            hence thesis by AAA,A123,A125,A142;
          end;
          suppose
A143:       x = t & y = tj;
            then f.x=e by A123;
            hence thesis by AAA,A123,A125,A143;
          end;
          suppose
A144:       x = t & y = dw;
            then f.x=e by A123;
            hence thesis by AAA,A123,A125,A144;
          end;
          suppose
A145:       x = t & y = td;
            then f.x=e by A123;
            hence thesis by AAA,A123,A125,A145;
          end;
        end;
      end;
A146: rng f c= ck
      proof
        let y be object;
        assume y in rng f;
        then consider x being object such that
A147:   x in dom f and
A148:   y=f.x by FUNCT_1:def 3;
        reconsider x as Element of N_5 by A147;
        x = z or x = tj or x = dw or x = td or x = t by A1,ENUMSET1:def 3;
        then y=a or y=d or y=c or y=b or y=e by A123,A148;
        hence thesis by ENUMSET1:def 3;
      end;
A149: dom f = the carrier of N_5 by FUNCT_2:def 1;
      ck c= rng f
      proof
        let y be object;
        assume
A150:   y in ck;
        per cases by A150,ENUMSET1:def 3;
        suppose
A151:     y=a;
          a = f.z by A123;
          hence thesis by A149,A151,FUNCT_1:def 3;
        end;
        suppose
A152:     y=b;
          b=f.td by A123;
          hence thesis by A149,A152,FUNCT_1:def 3;
        end;
        suppose
A153:     y=c;
          c = f.dw by A123;
          hence thesis by A149,A153,FUNCT_1:def 3;
        end;
        suppose
A154:     y=d;
          d=f.tj by A123;
          hence thesis by A149,A154,FUNCT_1:def 3;
        end;
        suppose
A155:     y=e;
          e=f.t by A123;
          hence thesis by A149,A155,FUNCT_1:def 3;
        end;
      end;
      then
A156: rng f = ck by A146;
A157: for x,y being Element of N_5 holds x <= y iff f.x <= f.y
      proof
        let x,y be Element of N_5;
        thus x <= y implies f.x <= f.y
        proof
          assume
A158:     x <= y;
          per cases by A1,ENUMSET1:def 3;
          suppose
            x=z & y=z;
            hence thesis;
          end;
          suppose
A159:       x=z & y=td;
            then
A160:       f.y = b by A123;
A161:       a <= b by A59,YELLOW_0:25;
            f.x = a by A123,A159;
            hence thesis by A160,A161,YELLOW_0:60;
          end;
          suppose
A162:       x=z & y=dw;
            then
A163:       f.y = c by A123;
A164:       a <= c by A60,YELLOW_0:25;
            f.x = a by A123,A162;
            hence thesis by A163,A164,YELLOW_0:60;
          end;
          suppose
A165:       x=z & y=tj;
A166:       b <= d by A64,YELLOW_0:25;
            a <= b by A59,YELLOW_0:25;
            then
A167:       a <= d by A166,ORDERS_2:3;
A168:       f.y = d by A123,A165;
            f.x = a by A123,A165;
            hence thesis by A168,A167,YELLOW_0:60;
          end;
          suppose
A169:       x=z & y=t;
A170:       c <= e by A61,YELLOW_0:25;
            a <= c by A60,YELLOW_0:25;
            then
A171:       a <= e by A170,ORDERS_2:3;
A172:       f.y = e by A123,A169;
            f.x = a by A123,A169;
            hence thesis by A172,A171,YELLOW_0:60;
          end;
          suppose
            x=td & y=z;
            then td c= z by A158,YELLOW_1:3;
            hence thesis by Th4;
          end;
          suppose
            x=td & y=td;
            hence thesis;
          end;
          suppose
A173:       x=td & y=dw;
A174:       not 2 in dw;
            2 in td by Th4,TARSKI:def 1;
            then not td c= dw by A174;
            hence thesis by A158,A173,YELLOW_1:3;
          end;
          suppose
            x=td & y=z;
            then td c= z by A158,YELLOW_1:3;
            hence thesis by Th4;
          end;
          suppose
A175:       x=td & y=tj;
            then
A176:       f.y = d by A123;
A177:       b <= d by A64,YELLOW_0:25;
            f.x = b by A123,A175;
            hence thesis by A176,A177,YELLOW_0:60;
          end;
          suppose
A178:       x=td & y=t;
A179:       d <= e by A62,YELLOW_0:25;
            b <= d by A64,YELLOW_0:25;
            then
A180:       b <= e by A179,ORDERS_2:3;
A181:       f.y = e by A123,A178;
            f.x = b by A123,A178;
            hence thesis by A181,A180,YELLOW_0:60;
          end;
          suppose
            x=dw & y=z;
            then dw c= z by A158,YELLOW_1:3;
            hence thesis;
          end;
          suppose
A182:       x=dw & y=td;
            0 in dw by CARD_1:50,TARSKI:def 2;
            then not dw c= td by Th4,TARSKI:def 1;
            hence thesis by A158,A182,YELLOW_1:3;
          end;
          suppose
            x=dw & y=dw;
            hence thesis;
          end;
          suppose
A183:       x=dw & y=tj;
            0 in dw by CARD_1:50,TARSKI:def 2;
            then not dw c= tj by Th3,TARSKI:def 2;
            hence thesis by A158,A183,YELLOW_1:3;
          end;
          suppose
A184:       x=dw & y=t;
            then
A185:       f.y = e by A123;
A186:       c <= e by A61,YELLOW_0:25;
            f.x = c by A123,A184;
            hence thesis by A185,A186,YELLOW_0:60;
          end;
          suppose
            x=tj & y=z;
            then tj c= z by A158,YELLOW_1:3;
            hence thesis by Th3;
          end;
          suppose
A187:       x=tj & y=td;
            1 in tj by Th3,TARSKI:def 2;
            then not tj c= td by Th4,TARSKI:def 1;
            hence thesis by A158,A187,YELLOW_1:3;
          end;
          suppose
A188:       x=tj & y=dw;
A189:       not 2 in dw;
            2 in tj by Th3,TARSKI:def 2;
            then not tj c= dw by A189;
            hence thesis by A158,A188,YELLOW_1:3;
          end;
          suppose
            x=tj & y=tj;
            hence thesis;
          end;
          suppose
A190:       x=tj & y=t;
            then
A191:       f.y = e by A123;
A192:       d <= e by A62,YELLOW_0:25;
            f.x = d by A123,A190;
            hence thesis by A191,A192,YELLOW_0:60;
          end;
          suppose
            x=t & y=z;
            then t c= z by A158,YELLOW_1:3;
            hence thesis;
          end;
          suppose
A193:       x=t & y=td;
            0 in t by CARD_1:51,ENUMSET1:def 1;
            then not t c= td by Th4,TARSKI:def 1;
            hence thesis by A158,A193,YELLOW_1:3;
          end;
          suppose
A194:       x=t & y=dw;
A195:       not 2 in dw;
            2 in t by CARD_1:51,ENUMSET1:def 1;
            then not t c= dw by A195;
            hence thesis by A158,A194,YELLOW_1:3;
          end;
          suppose
A196:       x=t & y=tj;
            0 in t by CARD_1:51,ENUMSET1:def 1;
            then not t c= tj by Th3,TARSKI:def 2;
            hence thesis by A158,A196,YELLOW_1:3;
          end;
          suppose
            x=t & y=t;
            hence thesis;
          end;
        end;
        thus f.x <= f.y implies x <= y
        proof
A197:     f.y in ck by A149,A156,FUNCT_1:def 3;
A198:     f.x in ck by A149,A156,FUNCT_1:def 3;
          assume
A199:     f.x <= f.y;
          per cases by A198,A197,ENUMSET1:def 3;
          suppose
            f.x = a & f.y = a;
            hence thesis by A124;
          end;
          suppose
A200:       f.x = a & f.y = b;
            f.z = a by A123;
            then z=x by A124,A200;
            then x c= y;
            hence thesis by YELLOW_1:3;
          end;
          suppose
A201:       f.x = a & f.y = c;
            f.z = a by A123;
            then z=x by A124,A201;
            then x c= y;
            hence thesis by YELLOW_1:3;
          end;
          suppose
A202:       f.x = a & f.y = d;
            f.z = a by A123;
            then z=x by A124,A202;
            then x c= y;
            hence thesis by YELLOW_1:3;
          end;
          suppose
A203:       f.x = a & f.y = e;
            f.z = a by A123;
            then z=x by A124,A203;
            then x c= y;
            hence thesis by YELLOW_1:3;
          end;
          suppose
            f.x = b & f.y = a;
            then b <= a by A199,YELLOW_0:59;
            hence thesis by AAA,A59,YELLOW_0:25;
          end;
          suppose
            f.x = b & f.y = b;
            hence thesis by A124;
          end;
          suppose
            f.x = b & f.y = c;
            then b <= c by A199,YELLOW_0:59;
            hence thesis by AAA,A63,YELLOW_0:25;
          end;
          suppose
A204:       f.x = b & f.y = d;
            f.tj = d by A123;
            then
A205:       y=tj by A124,A204;
            f.td = b by A123;
            then
A206:       x=td by A124,A204;
            Segm 1 c= Segm 2 by NAT_1:39;
            then x c= y by A206,A205,XBOOLE_1:34;
            hence thesis by YELLOW_1:3;
          end;
          suppose
A207:       f.x = b & f.y = e;
            f.t = e by A123;
            then
A208:       t = y by A124,A207;
            f.td = b by A123;
            then td=x by A124,A207;
            hence thesis by A208,YELLOW_1:3;
          end;
          suppose
            f.x = c & f.y = a;
            then c <= a by A199,YELLOW_0:59;
            hence thesis by AAA,A60,YELLOW_0:25;
          end;
          suppose
            f.x = c & f.y = b;
            then c <= b by A199,YELLOW_0:59;
            hence thesis by AAA,A63,YELLOW_0:25;
          end;
          suppose
            f.x = c & f.y = c;
            hence thesis by A124;
          end;
          suppose
            f.x = c & f.y = d;
            then c <= d by A199,YELLOW_0:59;
            hence thesis by AAA,A65,YELLOW_0:25;
          end;
          suppose
A209:       f.x = c & f.y = e;
A210:       dw c= t
            proof
              let X be object;
              assume X in dw;
              then X=0 or X=1 by CARD_1:50,TARSKI:def 2;
              hence thesis by CARD_1:51,ENUMSET1:def 1;
            end;
            f.t = e by A123;
            then
A211:       t = y by A124,A209;
            f.dw = c by A123;
            then dw=x by A124,A209;
            hence thesis by A210,A211,YELLOW_1:3;
          end;
          suppose
A212:       f.x = d & f.y = a;
A213:       a <= b by A59,YELLOW_0:25;
            d <= a by A199,A212,YELLOW_0:59;
            then d <= b by A213,ORDERS_2:3;
            hence thesis by AAA,A64,YELLOW_0:25;
          end;
          suppose
            f.x = d & f.y = b;
            then d <= b by A199,YELLOW_0:59;
            hence thesis by AAA,A64,YELLOW_0:25;
          end;
          suppose
            f.x = d & f.y = c;
            then d <= c by A199,YELLOW_0:59;
            hence thesis by AAA,A65,YELLOW_0:25;
          end;
          suppose
            f.x = d & f.y = d;
            hence thesis by A124;
          end;
          suppose
A214:       f.x = d & f.y = e;
            f.t = e by A123;
            then
A215:       t = y by A124,A214;
            f.tj = d by A123;
            then tj=x by A124,A214;
            hence thesis by A215,YELLOW_1:3;
          end;
          suppose
A216:       f.x = e & f.y = a;
A217:       b <= d by A64,YELLOW_0:25;
A218:       d <= e by A62,YELLOW_0:25;
            a <= b by A59,YELLOW_0:25;
            then a <= d by A217,ORDERS_2:3;
            then
A219:       a <= e by A218,ORDERS_2:3;
            e <= a by A199,A216,YELLOW_0:59;
            hence thesis by AAA,A219,ORDERS_2:2;
          end;
          suppose
A220:       f.x = e & f.y = b;
A221:       d <= e by A62,YELLOW_0:25;
            b <= d by A64,YELLOW_0:25;
            then
A222:       b <= e by A221,ORDERS_2:3;
            e <= b by A199,A220,YELLOW_0:59;
            hence thesis by AAA,A222,ORDERS_2:2;
          end;
          suppose
            f.x = e & f.y = c;
            then e <= c by A199,YELLOW_0:59;
            hence thesis by AAA,A61,YELLOW_0:25;
          end;
          suppose
            f.x = e & f.y = d;
            then e <= d by A199,YELLOW_0:59;
            hence thesis by AAA,A62,YELLOW_0:25;
          end;
          suppose
            f.x = e & f.y = e;
            hence thesis by A124;
          end;
        end;
      end;
      take f;
      f is one-to-one by A124;
      hence thesis by A68,A156,A157,WAYBEL_0:66;
    end;
  end;
end;
