theorem Th64:
  card H = card(H * a)
proof
  deffunc F(Element of G) = $1 * a;
  consider f being Function of the carrier of G, the carrier of G such that
A1: for g holds f.g = F(g) from FUNCT_2:sch 4;
  set g = f | (the carrier of H);
A2: dom f = the carrier of G & the carrier of H c= the carrier of G by
FUNCT_2:def 1,DefA5;
  then
A3: dom g = the carrier of H by RELAT_1:62;
A4: rng g = the carrier of H * a
  proof
    thus rng g c= the carrier of H * a
    proof
      let x be object;
      assume x in rng g;
      then consider y being object such that
A5:   y in dom g and
A6:   g.y = x by FUNCT_1:def 3;
      reconsider y as Element of H by A2,A5,RELAT_1:62;
      reconsider y as Element of G by Th42;
      f.y = y * a by A1;
      then x in carr H * a by A5,A6,Th41,FUNCT_1:47;
      hence thesis by Def6A;
    end;
    let x be object;
    assume x in the carrier of H * a;
    then x in carr H * a by Def6A;
    then consider b such that
A8: x = b * a and
A9: b in carr H by Th41;
A10: f.b = b * a by A1;
    g.b = f.b by A3,A9,FUNCT_1:47;
    hence thesis by A3,A8,A9,A10,FUNCT_1:def 3;
  end;
  g is one-to-one
  proof
    let x,y be object;
    assume that
A11: x in dom g and
A12: y in dom g and
A13: g.x = g.y;
    reconsider b = x, c = y as Element of H by A2,A11,A12,RELAT_1:62;
    reconsider b,c as Element of G by Th42;
A14: f.x = b * a & f.y = c * a by A1;
    f.x = g.x by A11,FUNCT_1:47;
    hence thesis by A12,A13,A14,ThB16,FUNCT_1:47;
  end;
  hence thesis by A3,A4,WELLORD2:def 4,CARD_1:5;
end;
