theorem
  for A,B be Matrix of len b1,len B2,K holds 
  Mx2Tran(A+B,b1,B2) = Mx2Tran(A,b1,B2) + Mx2Tran(B,b1,B2)
proof
  let A,B be Matrix of len b1,len B2,K;
  set AB=A+B;
  set M=Mx2Tran(A+B,b1,B2);
  set MA=Mx2Tran(A,b1,B2);
  set MB=Mx2Tran(B,b1,B2);
  now
    let x be object such that
A1: x in the carrier of V1;
    reconsider v=x as Element of V1 by A1;
    now
      per cases;
      suppose
A2:     len b1=0;
        hence M.x = 0.V2 by A1,Th33
          .= 0.V2+0.V2 by RLVECT_1:def 4
          .= MA.v+0.V2 by A2,Th33
          .= MA.v+MB.v by A2,Th33
          .= (MA+MB).x by MATRLIN:def 3;
      end;
      suppose
A3:     len b1>0;
        set L=LineVec2Mx(v|--b1);
A4:     width L=len (v|--b1) & len (v|--b1)=len b1 by MATRIX_0:23,MATRLIN:def 7
;
        set mB=lmlt(Line(L*B,1),B2);
A5:     len B=len b1 & width B=len B2 by A3,MATRIX_0:23;
        then
A6:     width (L*B)=len B2 by A4,MATRIX_3:def 4;
        then len Line(L*B,1)=len B2 by CARD_1:def 7;
        then dom Line(L*B,1)=dom B2 by FINSEQ_3:29;
        then
A7:     dom mB=dom B2 by MATRLIN:12;
        then
A8:     len mB=len B2 by FINSEQ_3:29;
A9:     len A=len b1 by A3,MATRIX_0:23;
        len L=1 by MATRIX_0:23;
        then
A11:    len (L*A)=1 by A9,A4,MATRIX_3:def 4;
        set mA=lmlt(Line(L*A,1),B2);
A12:    width A=len B2 by A3,MATRIX_0:23;
        then
A13:    width (L*A)=len B2 by A9,A4,MATRIX_3:def 4;
        then len Line(L*A,1)=len B2 by CARD_1:def 7;
        then dom Line(L*A,1)=dom B2 by FINSEQ_3:29;
        then
A14:    dom mA=dom B2 by MATRLIN:12;
        then
A15:    len mA=len B2 by FINSEQ_3:29;
A16:    dom (mA+mB) = dom B2/\dom B2 by A14,A7,Lm3
          .= dom B2;
        then
A17:    len (mA+mB)=len B2 by FINSEQ_3:29;
A18:    now
          let k be Nat such that
A19:      k in dom mA;
          mA/.k=mA.k & mB/.k=mB.k by A14,A7,A19,PARTFUN1:def 6;
          hence (mA+mB).k = mA/.k + mB/.k by A14,A16,A19,FVSUM_1:17;
        end;
        thus M.x = Sum lmlt (Line(L * AB,1),B2) by Def3
          .= Sum lmlt (Line(L * A+L*B,1),B2) by A9,A12,A5,A4,MATRIX_4:62
          .= Sum lmlt (Line(L * A,1)+Line(L*B,1),B2)by A11,A13,A6,Lm5
          .= Sum (mA + mB) by Th7
          .= Sum mA +Sum mB by A15,A8,A17,A18,RLVECT_2:2
          .= MA.v+Sum mB by Def3
          .= MA.v+MB.v by Def3
          .= (MA+MB).x by MATRLIN:def 3;
      end;
    end;
    hence M.x=(MA+MB).x;
  end;
  hence thesis by FUNCT_2:12;
end;
