theorem Th63:
  0.R <> 1_R & A is linearly-independent implies not 0.V in A
proof
  assume that
A1: 0.R <> 1_R and
A2: A is linearly-independent and
A3: 0.V in A;
  deffunc F(Element of V)=0.R;
  consider f being Function of the carrier of V, the carrier of R such that
A4: f.(0.V) = 1_R and
A5: for v being Element of V st v <> 0.V holds f.v = F(v) from FUNCT_2:
  sch 6;
  reconsider f as Element of Funcs(the carrier of V, the carrier of R) by
FUNCT_2:8;
  ex T being finite Subset of V st for v st not v in T holds f.v = 0.R
  proof
    take T = {0.V};
    let v;
    assume not v in T;
    then v <> 0.V by TARSKI:def 1;
    hence thesis by A5;
  end;
  then reconsider f as Linear_Combination of V by Def2;
A6: Carrier(f) = {0.V}
  proof
    thus Carrier(f) c= {0.V}
    proof
      let x be object;
      assume x in Carrier(f);
      then consider v such that
A7:   v = x and
A8:   f.v <> 0.R;
      v = 0.V by A5,A8;
      hence thesis by A7,TARSKI:def 1;
    end;
    let x be object;
    assume x in {0.V};
    then x = 0.V by TARSKI:def 1;
    hence thesis by A1,A4;
  end;
  then Carrier(f) c= A by A3,ZFMISC_1:31;
  then reconsider f as Linear_Combination of A by Def5;
  Sum(f) = 0.V * f.(0.V) by A6,Th35
    .= 0.V by VECTSP_2:32;
  hence contradiction by A2,A6;
end;
